PPT편집창에서 더블클릭으로 링크된 파일 실행하기

AutoHotKey

PPT편집창에서 더블클릭으로 링크된 파일 실행하기

쵸코난 2024. 7. 15. 23:52

슬라이드 편집 상태에서는 'Ctrl+클릭'을 눌러야 하이퍼링크나 프로그램을 실행합니다.

Ctrl+클릭을 누르면 링크된 파일에 대한 보안알림창이 떠서 번거롭습니다.

다른 단축키 중에 더블클릭은 텍스트상자의 경우 이미 도형내 텍스트 편집으로 지정되어 있어서 사용이 불가능합니다.

아니면 슬라이드쇼를 실행해야 한 번의 클릭만으로 프로그램 실행이나 파일 열기가 가능합니다.

1. 슬라이드 편집상태에서 아이콘이나 그림 등을 더블 클릭시 열리게 하려면

일단 삽입 > 개체를 이용해서 이미지 파일 등을 개체로 삽입하면 더블 클릭하면 파일이 열리게 할 수 있습니다.

개체의 아이콘이나 그림을 바꾸려면 아래 답변을 참고해서 투명 아이콘을 사용하고 그림을 채워넣으면 됩니다.

https://kin.naver.com/qna/detail.naver?d1id=1&dirId=102020103&docId=471655420

2. 특별히 슬라이드 편집 상태에서 더블 클릭으로 연결된 링크를 실행하고 싶다면

아래 AutoHotKey 스크립트로 만든 프로그램을 이용해보세요.

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.
CoordMode, Mouse, Screen

	WinSetTitle, DblClickRun

	msgbox,0x40,DblClickRun,DoubleClick the shape to run the target link on a PPT slide `n`n[Win+a] to deActivate/Activate`, [Win+X] to quit
	;Menu, Tray, Icon, shell32.dll, 20
	Menu, Tray, NoStandard
	Menu, Tray, Add, Active, MenuHandler
	Menu, Tray, Add, Unactive, MenuHandler
	Menu, Tray, Add, Exit, ExitMenu
	Active := False
	goto MenuHandler
return

MenuHandler:
	Active := !Active
	if (Active) {
		Menu, Tray, Check, Active
		Menu, Tray, Uncheck, Unactive
		Menu, Tray, Disable, Active
		Menu, Tray, Enable, Unactive
		Menu, Tray, Tip, Active`, [Win+a]: DeActivate  [Win+X]: Exit
		Menu, Tray, Icon, %A_ScriptFullPath%, 1
	} else	{
		Menu, Tray, Check, Unactive
		Menu, Tray, Uncheck, Active
		Menu, Tray, Enable, Active
		Menu, Tray, Disable, Unactive
		Menu, Tray, Tip, Not Active`, [Win+a]: Activate  [Win+X]: Exit
		Menu, Tray, Icon, %A_ScriptFullPath%, 5
	}
return

#a::
	Goto MenuHandler

return

#IfWinActive, ahk_class PPTFrameClass
~LButton::
	If (Active) {
		If (A_ThisHotkey = A_PriorHotkey and A_TimeSincePriorHotkey < 200) {
			try {
				ppt:=ComObjActive("PowerPoint.Application")
				;ppt.Visible := True
				shp := ppt.ActiveWindow.Selection.ShapeRange(1)
				link := shp.ActionSettings(1).Hyperlink		;1:ppMouseClick
				linkAddr := link.Address
				if (StrLen(linkAddr)>4) {
					;msgbox, %linkAddr%
					;link.Follow
					Run, open %linkAddr%
				}
				;send, ^{LeftClick}

			}
			catch e {
				;no powerpoint
			}
		}
	}
return
#IfWinActive

ExitMenu:
#x::
exitapp

첨부한 exe파일의 속성에서 차단해제한 다음 실행합니다.