konahn　　　　　　　A PowerPoint VBA Adventurer

[Bomb Game] 상시 점수판 + Bomb 퀴즈 만들기 - PPT 스킬 퀴즈

쵸코난 — Mon, 11 May 2026 00:36:50 +0900

✅ 이번 버전의 특징

기존 Bomb Game 은 점수판을 문제를 풀고 나서만 확인할 수 있었는데

이번 버전은 팀별 점수판이 번호 선택할 때나 문제를 풀 때나 항상 오른쪽에 뜨도록 만든 버전입니다.

점수판은 슬라이드 마스터 레이아웃에 들어 있기 때문에 슬라이드에 점수판 레이아웃만 적용하면 됩니다.

이번에는 샘플로 PPT 기능에 대한 내용을

문제를 풀고 돌아오면 번호가 사라지는 점수판 Bomb Game 형식으로 생성했습니다.

자주 받는 질문인데 하이퍼링크 걸린 번호 도형이 나중에 사라지는 것은 Bomb Game 제작 방법 링크를 참고하세요.

✅ Bomb Game 숫자 버튼 생성 자동화

Bomb Game 만들 때 숫자 버튼이 20개이상 많다면 일일이 하이퍼링크와 트리거 애니메이션을 각각 적용하는 것이 무척 번거롭습니다. 이 작업은 매크로로 자동화할 수 있습니다.

pptm 첨부파일에서 3슬라이드를 선택하고 기존 버튼을 지우고 Alt+F8을 누르면 뜨는 매크로 목록에서

C_BombChoice를 누르면 자동으로 숫자 버튼을 생성하고 하이퍼링크와 트리거 애니메이션을 적용해줍니다.

◆◆◆ ◆◆◆ ◆◆◆

✅ Bomb Game 모든 작업 원클릭 자동화

궁극적으로는 가장 위에 있는 A_Main 을 누르면 Bomb Game 제작 전체 과정을 완전 자동화 처리합니다.

A_Main 매크로는 일련의 작업을 한꺼번에 처리해줍니다.

엑셀파일에 정리한 문제 목록으로부터 4번 슬라이드 템플릿 슬라이드를 바탕으로 그 틀 그대로 자동으로 모든 문제 슬라이드를 생성하고 문제 선택 슬라이드에 Bomb Game 숫자 버튼을 원하는 개수와 배열로 만들고 문제 슬라이드로 하이퍼링크와 사라지기 트리거 애니메이션을 자동으로 지정해줍니다.

또한 추후에라도 엑셀목록으로부터 문제 슬라이드를 자동으로 생성(B_LoadXL)하고

숫자버튼의 색상을 랜덤으로 수정(D_Buttons_Color/ G_ColorForSimilarButtons)하고

문제슬라이드 순서를 섞기도(E_QSlideShuffle_Range) 합니다.

그리고 마지막 슬라이드에 매크로가 필요 없는 점수판을 만들어주기도(F_TeamScore) 합니다.

이번에는 위에 설명한 대로 마지막에만 점수를 보여주지 않고 슬라이드 마스터 레이아웃을 이용해 항상 옆에 점수판이 뜨게 했습니다.

✅ AI를 이용한 문제 자동 생성

문제슬라이드 생성은 몇번 소개한대로 아래 프롬프트처럼 AI에게 문제를 CSV파일 형식으로 생성해달라고 해서

그 결과를 엑셀에 붙여넣으면 빠르게 문제 생성이 가능합니다.

'파워포인트 숨은 기능 사용법'에 대한 집중 훈련 세트를 만들려고 해. 아래 조건에 맞춰서 모르기 쉬운 기능에 대한 질문 30개를 생성해줘.
핵심 영역: 슬라이드 생성/복제, 도형/텍스트상자 속성, 문단속성, 슬라이드마스터, 전환효과, 클릭 애니메이션, 트리거 애니메이션, 하이퍼링크, 슬라이드쇼 설정, 글꼴포함, 도형병합, 동영상 삽입  
구성 비율: 핵심영역 중에서 균형을 맞춰 출제해줘.
난이도: 초보 파워포인트 사용자가 가장 모르고 실수하는 기능을 반영해줘.
출력 형식: 반드시 아래의 CSV 코드 블록 형식으로 출력해줘. (쉼표로 구분할 때 문장 내 쉼표와 충돌하지 않도록 큰따옴표 """"를 사용해줘.)
헤더: No,구분,문제,정답,설명
예시 줄:
1,슬라이드쇼,""슬라이드쇼에서 애니메이션 없이 슬라이드만 보게 하려면?"",""슬라이드쇼 설정 > 애니메이션 효과 없음에 체크하고 쇼를 시작한다."", 슬라이드쇼 설정 대화상자를 확인하세요.
2,글꼴,다른컴퓨터에서 글꼴을 유지하려면?,파일 > 옵션 > 고급 >저장에서 글꼴포함에 체크하고 저장, 편집이 필요 없으면 > 사용한 글꼴만 포함, 편집이 필요하면 > 모든 글꼴 포함"

결과 텍스트를 엑셀에 붙여넣고 데이터 > 텍스트나누기 > 쉼표로 분할

◆◆◆ ◆◆◆ ◆◆◆

✅ 슬라이드 마스터를 이용한 상시 점수판

원래 점수판이 맨 뒤에 들어가는데

이번에는 점수가 오른쪽에 항상 뜨도록 슬라이드 마스터 레이아웃을 이용했습니다.

오른쪽에 10개 팀의 점수가 나오려면 살짝 수정이 필요합니다.

예전 코드에서 MaxT를 10으로 수정해야 하는데 이번에는 원하는 팀 개수와 세로 행수를 선택할 수 있습니다.

첨부파일에는 6개 팀으로 만들어 보았으니 참고하세요.

팀 점수판이 있는 슬라이드를 다른 ppt에 붙여넣기하고 Module 4 매크로 코드를 복사해도 됩니다.

팀 개수를 원하는 개수로 변경하려면 pptm 파일 다운로드하고

3슬라이드 이후의 아무 슬라이드에서 보기 > 슬라이드 마스터로 이동합니다.

Score_A 그룹도형이 있는 레이아웃을 선택하고 나머지 Score_x 도형은 삭제한 상태에서

Alt+F8 매크로 > H_ResetTeamScoreBoard 를 실행하고 '10, 10' 을 입력하면

10개 점수판을 세로 최대 10행에 맞춰서 10팀 * 1 열로 점수판을 삽입해줍니다.

단, Score_A 그룹도형이 반드시 존재해야 합니다.

만약 '8, 4'를 입력하면 총 8개팀을 4개씩 * 2열로 만들어줍니다.

'6, 6'을 입력하면 6팀 * 1열로 점수판을 생성합니다.

팀이름은 슬라이드 마스터 점수판 레이아웃에서 직접 수정하거나

슬라이드쇼에서 팀 이름을 클릭하면 팀 이름을 하나씩 수정할 수 있습니다.

✅ 실행 화면

실행화면1

실행화면2

실행화면3

✅ 상시 점수판 기능의 장단점

- 슬라이드 마스터를 이용해서 어떤 슬라이드든 점수판을 쉽게 보여줄 수 있음.

- 점수를 상시 확인 가능

- 슬라이드 마스터 레이아웃에 점수판이 있기 때문에 슬라이드에 의해 가려질 수 있음.

- 점수판 영역을 남겨놔야해서 메인 슬라이드나 문제 슬라이드가 다소 좁아지는 단점이 있음.

✅ 샘플 파일 다운로드

샘플 문제목록 엑셀 파일과

ppt 매크로 파일 첨부합니다.

✅ 매크로 파일 실행시 유의사항

- pptm 파일을 다운로드한 경우 파일 속성에서 차단해제합니다.

(365에서는 외부에서 다운로드한 pptm 파일을 차단해제하지 않으면 열 수 없습니다.)

- 최초 파일을 열 때 반드시 '매크로 컨텐트 허용' 버튼을 눌러줘야 합니다.

- 파워포인트 보안설정에서 모든 매크로 제외(알림표시) 이상으로 보안이 허용되어 있어야 합니다.

알림표시가 선택되어야 '매크로 콘텐츠 사용' 알림이 떠서 사용자가 허용할 수 있습니다.(이 설정이 파워포인트 기본 설정입니다.)

연결로 삽입된 미디어 경로 일괄 수정

쵸코난 — Wed, 25 Mar 2026 23:18:46 +0900

관련: 지식인

요즘에는 pptx로 저장하면 기본으로 오디오가 pptx파일내에 포함되어 저장됩니다.

과거 형식인 .ppt 로 저장하거나 pptx에서도 삽입 버튼에서 파일에 연결을 선택하면 오디오 파일은 포함되지 않고 링크로 삽입됩니다.

이렇게 연결로 삽입하면 pptx파일을 다른 곳으로 옮기게 되면

경로가 맞지 않아 파일 재생에 문제가 생기고 오류 메시지가 뜹니다.

이럴 때 미디어의 연결 링크를 일괄로 수정하는 방법을 안내합니다.

1. 연결 편집

일단 파일 > 정보 화면 에서 오른쪽 아래에 파일 연결 편집 메뉴가 있습니다.

이걸 눌러서 파일들의 위치가 어떻게 설정되어 있는지 보시고

똑같은 폴더에 해당 파일들을 옮기시면 재생이 될 겁니다.

원본 변경 버튼을 눌러 하나씩 변경할 수도 있습니다.

2. VBA이용 방법

VBA로 연결로 삽입된 모든 미디어에 대해

폴더 경로를 제거하고 pptx파일이 있는 현재 폴더로 변경하고 링크를 업데이트하도록

할 수 있습니다.

Alt+F11 누르고 삽입 > 모듈을 추가한 다음 아래 코드를 복사해서 붙여넣습니다.

그 다음 F5로 매크로를 실행하면 됩니다.

Sub RemovePathFromMediaLink()

    Dim prs As Presentation
    Dim sld As Slide, shp As Shape
    
    Set prs = ActivePresentation
    
    For Each sld In prs.Slides
        For Each shp In sld.Shapes
            If shp.Type = msoMedia Then
                If shp.MediaFormat.IsLinked Then
                    Debug.Print "Slide #" & sld.SlideIndex
                    sname = shp.LinkFormat.SourceFullName
                    Debug.Print sname
                    sname = Mid(sname, InStrRev(sname, "\") + 1)
                    shp.LinkFormat.SourceFullName = sname
                    shp.LinkFormat.Update
                    Debug.Print "==> " & shp.LinkFormat.SourceFullName
                End If
            End If
        Next shp
    Next sld
    
End Sub

위 코드는 C:\Users\user1\Downloads\mute04.mp3 같은 경로를 mute04.mp3 로 만들어줍니다.

그래서 pptx파일이 있는 현재 폴더에 해당 파일이 있으면 재생이 가능해집니다.

아니면 sname = Replace(sname, "C:\Users\User1", "C:\Users\User2") 같은 방식으로 특정 경로를 다른 경로로 수정해도 됩니다.

3. XML 프레젠테이션으로 저장 후 경로 일괄 바꾸기

파일 > 다른이름으로 저장에서 Powerpoint XML 프레젠테이션으로 저장합니다.

저장한 XML 파일을 텍스트 편집기에서 열어서

텍스트 찾아 바꾸기 기능을 이용해서 C:\Users\user1\Desktop\와 같은 경로를 C:\Users\user2\Desktop\ 로 변경합니다.

경로 이름이 조금이라도 틀리면 오류가 발생하고 경로가 한 개가 아니므로

주의해서 정확히 입력해서 교체합니다.

저장한 XML 파일을 다시 파워포인트에서 불러와서 다시 .pptx 혹은 .ppt로 저장합니다.

4. 연결로 삽입된 링크 연결해제(파일에 포함) 시키기

연결로 삽입된 미디어들을 pptx파일에 포함시키도록 일괄로 바꾸는 코드입니다.

(Alt+F11 누르고 삽입 > 모듈을 추가한 다음 아래 코드를 복사해서 붙여넣습니다.

그 다음 F5로 매크로를 실행)

Sub reEmbedLinkedMedia()

    Dim prs As Presentation
    Dim sld As Slide, shp As Shape
    
    Set prs = ActivePresentation
    
    For Each sld In prs.Slides
        For Each shp In sld.Shapes
            If shp.Type = msoMedia Then
                If shp.MediaFormat.IsLinked Then
                    Debug.Print "Slide #" & sld.SlideIndex
                    sname = shp.LinkFormat.SourceFullName
                    Debug.Print sname
                    shp.LinkFormat.BreakLink
                    Debug.Print "Embedding result ==> " & shp.MediaFormat.IsEmbedded
                End If
            End If
        Next shp
    Next sld
    
End Sub

엑셀링크목록 브라우저 북마크에 일괄로 추가하기

쵸코난 — Wed, 18 Mar 2026 00:44:59 +0900

엑셀에 정리한 URL목록을 일괄로 웹브라우저 북마크로 추가할 수 있게 도와주는 VBA매크로입니다.

일단 아래와 같이 엑셀에 URL을 정리했습니다.

이 링크들을 일괄로 웹브라우저 북마크에 폴더를 하나 만들어 추가하고 싶습니다.

물론 모든 링크를 클릭해서 웹브라우저 탭에 띄운 다음

열린 탭들을 북마크에 추가할 수 있습니다.

하지만 모든 링크를 여는 것은 번거로운 작업입니다.

그래서 엑셀VBA로 이 과정을 자동으로 처리합니다.

핵심 원리는 웹브라우저 북마크를 내보내면 아래와 같은 HTML양식인데

이 양식에 맞게 VBA로 북마크 HTML을 만들면 되겠습니다.

특히 초반 헤더 부분과

<DL> Description List 태그와

<DT> Description Term 태그를 이용합니다.

원래는 DT 다음에 <DD> Description Description 이 따라오는데 생략합니다.

<DL>

<DT><A HREF="https://your-link2.com">링크2</A>...

</DL>

이런 식입니다.

엑셀 URL 목록에 대해 위와 같은 양식으로 HTML 텍스트 파일을 생성하게 하면 됩니다.

Gemini에게 코드를 만들도록 시키고 약간만 수정했습니다.

먼저 html파일을 UTF-8 인코딩으로 만드는 경우입니다.

일본어, 중국어, 프랑스어 등 다른 나라 언어글자가 포함되는 경우

ADODB.Stream을 이용해 UTF-8 인코딩방식으로 텍스트파일을 만들어야 모든 언어가 제대로 보입니다.

Sub ExportToChromeBookmarks()

    Dim ws As Worksheet
    Dim lastRow As Long
    Dim i As Long
    Dim siteName As String
    Dim siteURL As String
    Dim filePath As Variant
    Dim stream As Object
    Dim sBookPath As String
    
    ' 현재 활성화된 시트를 기준으로 작업
    Set ws = ActiveSheet
    sBookPath = ws.Name
    
    ' A열의 마지막 데이터 행 찾기
    lastRow = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row
    
    ' 데이터가 없으면 종료
    If lastRow < 1 Then
        MsgBox "출력할 데이터가 없습니다. A열과 B열에 데이터를 입력해주세요.", vbExclamation
        Exit Sub
    End If
    
    ' 북마크 제목
    sBookPath = InputBox("북마크 제목(Title)을 입력하세요." & vbNewLine & _
        "(크롬에서는 북마크를 불러오면 해당이름의 폴더 아래 북마크들이 생성됩니다.)", "Bookmark Title 입력", sBookPath)
    If Len(sBookPath) = 0 Then Exit Sub
    
    ' 저장할 파일 경로 및 이름 지정 대화상자 열기
    filePath = Application.GetSaveAsFilename(InitialFileName:=ws.Parent.Path & "\Chrome_Bookmarks.html", _
                                             FileFilter:="HTML Files (*.html), *.html", _
                                             Title:="북마크 파일 저장 위치 선택")
    
    ' 취소를 누른 경우 종료
    If filePath = False Then Exit Sub
    
    ' 한글 깨짐 방지를 위해 UTF-8 인코딩으로 파일 저장을 돕는 ADODB.Stream 객체 생성
    Set stream = CreateObject("ADODB.Stream")
    stream.Type = 2 ' 텍스트 타입
    stream.Charset = "utf-8" ' UTF-8 인코딩
    stream.Open
    
    ' 크롬 북마크 표준 HTML 헤더 작성
    stream.WriteText "<!DOCTYPE NETSCAPE-Bookmark-file-1>" & vbCrLf
    stream.WriteText "" & vbCrLf
    stream.WriteText "<META HTTP-EQUIV=""Content-Type"" CONTENT=""text/html; charset=UTF-8"">" & vbCrLf
    stream.WriteText "<TITLE>Bookmarks</TITLE>" & vbCrLf
    stream.WriteText "<H1>Bookmarks</H1>" & vbCrLf
    stream.WriteText "<DL><p>" & vbCrLf
    stream.WriteText "<DT><H3>" & sBookPath & "</H3>" & vbCrLf         'Bookmark Folder Name
    stream.WriteText "<DL><p>" & vbCrLf
    
    ' 2행부터 마지막 행까지 순회하며 데이터 추출
    For i = 2 To lastRow
        siteName = ws.Cells(i, 1).Value ' A열: 사이트 이름
        siteURL = ws.Cells(i, 2).Value  ' B열: URL
        
        ' 이름과 URL이 모두 있는 경우에만 북마크 태그 추가
        If Trim(siteName) <> "" And Left(Trim(siteURL), 4) Like "http" Then
            ' <DT><A HREF="URL">사이트이름</A> 형식으로 추가
            stream.WriteText "    <DT><A HREF=""" & siteURL & """>" & siteName & "</A>" & vbCrLf
        End If
    Next i
    
    ' 꼬리말 작성
    stream.WriteText "</DL><p>" & vbCrLf
    stream.WriteText "</DL><p>" & vbCrLf
    
    ' 파일로 저장 (adSaveCreateOverWrite = 2 : 덮어쓰기 허용)
    stream.SaveToFile filePath, 2
    stream.Close
    
    MsgBox "크롬 북마크 파일이 성공적으로 생성되었습니다!" & vbCrLf & _
           "저장 경로: " & filePath, vbInformation
End Sub

한글, 영어만 사용하는 경우 아래와 같이 ANSI인코딩으로 HTML 텍스트파일을 만들어도 됩니다.

Sub ExportToChromeBookmarks_ANSI()
    Dim ws As Worksheet
    Dim lastRow As Long
    Dim i As Long
    Dim siteName As String
    Dim siteURL As String
    Dim filePath As Variant
    Dim fileNum As Integer
    
    ' 현재 활성화된 시트를 기준으로 작업
    Set ws = ActiveSheet
    
    ' A열의 마지막 데이터 행 찾기
    lastRow = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row
    
    ' 데이터가 없으면 종료
    If lastRow < 1 Then
        MsgBox "출력할 데이터가 없습니다. A열과 B열에 데이터를 입력해주세요.", vbExclamation
        Exit Sub
    End If
     
    ' 북마크 제목
    sBookPath = InputBox("북마크 제목(Title)을 입력하세요." & vbNewLine & _
        "(크롬에서는 북마크를 불러오면 해당이름의 폴더아래 북마크들이 생성됩니다.)", "Bookmark Title 입력", sBookPath)
    If Len(sBookPath) = 0 Then Exit Sub
    
    ' 저장할 파일 경로 및 이름 지정 대화상자 열기
    filePath = Application.GetSaveAsFilename(InitialFileName:=ws.Parent.Path & "\Chrome_Bookmarks.html", _
                                             FileFilter:="HTML Files (*.html), *.html", _
                                             Title:="북마크 파일 저장 위치 선택")
    
    ' 취소를 누른 경우 종료
    If filePath = False Then Exit Sub
    
    ' 사용 가능한 빈 파일 번호 가져오기
    fileNum = FreeFile
    
    ' 기본 텍스트 파일 쓰기 모드로 열기 (ANSI 인코딩)
    Open filePath For Output As #fileNum
    
    ' 크롬 북마크 표준 HTML 헤더 작성
    Print #fileNum, "<!DOCTYPE NETSCAPE-Bookmark-file-1>"
    Print #fileNum, ""
    ' 주의: 파일은 ANSI로 저장되지만 크롬 규격상 헤더에는 UTF-8로 명시해 둡니다.
    Print #fileNum, "<META HTTP-EQUIV=""Content-Type"" CONTENT=""text/html; charset=ansi"">"
    Print #fileNum, "<TITLE>Bookmarks</TITLE>"
    Print #fileNum, "<H1>Bookmarks</H1>"
    Print #fileNum, "<DL><p>"
    Print #fileNum, "<DT><H3>" & ws.Name & "</H3>" & vbCrLf         'Bookmark Folder Name
    Print #fileNum, "<DL><p>" & vbCrLf
    
    ' 2행부터 마지막 행까지 순회하며 데이터 추출
    For i = 2 To lastRow
        siteName = ws.Cells(i, 1).Value ' A열: 사이트 이름
        siteURL = ws.Cells(i, 2).Value  ' B열: URL
        
        ' 이름과 URL이 모두 있는 경우에만 북마크 태그 추가
        If Trim(siteName) <> "" And Left(Trim(siteURL), 4) Like "http" Then
            ' <DT><A HREF="URL">사이트이름</A> 형식으로 기록
            Print #fileNum, "    <DT><A HREF=""" & siteURL & """>" & siteName & "</A>"
        End If
    Next i
    
    ' 꼬리말 작성
    Print #fileNum, "</DL><p>"
    Print #fileNum, "</DL><p>"
    
    ' 파일 닫기
    Close #fileNum
    
    MsgBox "크롬 북마크 파일이 성공적으로 생성되었습니다!" & vbCrLf & _
           "저장 경로: " & filePath, vbInformation
End Sub

엑셀에 URL을 정리하고

Alt+F8을 눌러 매크로창에서

둘 중의 하나의 매크로를 실행하면 아래처럼 북마크 HTML을 생성합니다.

대화상자가 뜨면 북마크 제목을 확인하고 수정합니다. 북마크 제목은 <h3> 태그로 문서의 부제목 역학인데 생성된 북마크 HTML을 크롬브라우저에서 불러오면 이 폴더 이름 아래에 북마크들이 생성됩니다. 다른 브라우저에서는 영향이 없습니다.

생성된 Chrome_Bookmarks.html 입니다.

이제 웹브라우저에서 북마크 가져오기를 누르고 이 HTML파일을 불러오면 됩니다.

크롬, 엣지, 웨일 등 크롬 기반 웹브라우저에서 Ctrl+Shift+O를 누르고 북마크 관리자를 켭니다.

그 다음 오른쪽 상단 점 세개를 누르고 북마크 가져오기를 누르고 북마크 HTML파일을 선택합니다.

(참고로 기존 북마크 폴더가 없다면 폴더를 하나 만들고 가져오는 것이 좋을 수 있습니다.)

아래처럼 크롬에서는 지정된 폴더(myFolder)가 만들어지고 그 안에 북마크가 일괄 생성됩니다.

크롬에서는 북마크 HTML에서 <H3> 태그 안의 내용대로 폴더가 만들어지는 것으로 보입니다.

다른 브라우저에서는 '가져온 북마크'라는 폴더안에 생성됩니다.

엣지에서 즐겨찾기 가져오기:

Ctrl+Shift+O 누르고 즐겨찾기 가져오기 > HTML 파일 > 파일선택

파이어폭스에서 북마크 가져오기:

Ctrl+Shift+O누르고 가져오기 > HTML에서 북마크 가져오기

✅ 매크로가 포함된 샘플 파일입니다:

SaveAsBookmark1.xlsm

0.04MB

참고: addHyperlink2Self 매크로는

엑셀에서 B열의 URL링크에 대해 자기자신에게 하이퍼링크를 일괄로 적용해줍니다.

✔️ 자바스크립트 버전:

엑셀 등의 표를 아래 사이트에 붙여 넣고 Generate 버튼을 누르면 HTML로 만들어줍니다.

이 내용을 복사해서 HTML파일로 저장하세요.

원본은 https://jsfiddle.net/k0m9rqho/show인데 로그인이 필요해서 약간 수정해서 다른 데 올려놨습니다.

http://handin.woobi.co.kr/bookmark/

Copy the text below and save it as an .html file. Open your browser's Bookmark Manager (Ctrl+Shift+O), then select 'Import Bookmarks' from the menu to upload the file. ✨ 사용 방법: 1. 위 박스의 내용을 복사하여 메모장에 붙여넣고

handin.woobi.co.kr

구글 시트에서 바로 사용 가능한 AI 함수

쵸코난 — Sat, 14 Mar 2026 22:42:58 +0900

구글 시트의 셀에서 =GPT("prompt") 수식으로 바로 AI명령 실행이 가능하다.

엑셀 VBA로 Gemini에게 명령을 보내 결과값을 가져오는 함수를 만든적이 있습니다.

그런데 추가기능에서 이미 함수를 제공하고 있네요.

GPT for Sheets and Docs

제일 많이 알려지고 설치된 것은 'GPT for Sheets and Docs'라는 추가기능이 있습니다.

확장프로그램 > 부가기능 > 부가기능 설치하기 에서 검색을 해서 추가기능을 설치하면

이제 구글 시트상에서 원하는 셀에 =GPT ( "프롬프트 명령", 값(명령에 덧붙여질 값, 생략가능), 온도(0~1사이), 사용할모델) 과 같은 함수식을 이용할 수 있습니다.

간단히 특정 단어에 대한 예문을 생성하라고 한다면

=GPT(A1 & "라는 영어단어를 사용한 예문을 하나만 만들어줘") 라고 입력하면

잠시 뒤에 결과값을 가져옵니다.

그 밖에 사용할 수 있는 GPT 명령들입니다. 오른쪽 추가기능 창과 도움말에서 확인 가능합니다.

GPT는 주로 하나의 셀에 결과를 받아오지만(여러 행에 결과를 출력하기도 함)

GPT_LIST 는 결과값을 여러행으로 가져올 수 있습니다.

특히 GPT_LIST는 위와 같이 여러 단어에 대한 결과값을 한꺼번에 가져 올 수 있어 매우 유용합니다.

아래와 같은 형식입니다.

두번째 인수인 Value 값에 해당 영역을 지정해서 여러 셀(단어)를 넘겨서 결과값도 한 번에 아래로 쭉 출력할 수 있습니다.

=GPT_LIST("다음 영어 단어를 사용하는, 수준 높은 대표적인 짧은 영어 예문 하나만 만들어줘. 영어 문장만 출력해.",B23:B31,0.8,"gpt-4.1")

이 함수는 한개의 셀에만 입력하면 결과가 아래로 쭉 대상 셀들 옆에 값들이 출력됩니다. 각 셀에 함수식을 입력할 필요가 없습니다.

그밖에 GPT_Extract는 문자열에서 인공지능이 계산해서 값을 추출합니다.

ex) =GPT_EXTRACT("I worked 12 years at Amazon.com and Apple", "companies") 를 입력하면 'Amazon.com, Apple' 이라는 회사명을 찾아 줍니다.

GPT_Format은 문자열을 인공지능계산으로 특정 형식으로 만듭니다.

ex) =GPT_FORMAT("14 February 71", "iso")
=GPT_FORMAT("8201012345678","international phone number") => +82 10 1234 5678

GPT_SPLIT은 인공지능으로 문자열을 분리해줍니다.
ex) =GPT_SPLIT("Hello! How are you? Have you heard of GPT for Sheets?","sentences")
=GPT_HSPLIT("Hello! How are you? Have you heard of GPT for Sheets?","sentences") => 세로 행으로 결과 출력

GPT_CLASSIFY는 인공지능이 나열된 값들이 속한 분류를 추측해냅니다.

=GPT_CLASSIFY("banana", "fruit, "vegetable") => fruit

GPT_MATCH 는 인공지능판 VLookup 같은 함수입니다.

https://www.youtube.com/watch?v=xKqrn9m4PLo&t=8s

=GPT_MATCH(search_keys, lookup_range, [confidence], [stats], [top_k])

ex) =GPT_MATCH(A1:A10,B1:B4) 는 B1:B4 에 대해서 A1:A10의 값과 비교해서 유사성이 있는 결과값을 출력합니다.

=GPT_MATCH(A1:A10,B1:B4, ,True) 로 stats 옵션을 켜면 옆에 유사도를 소숫점으로 표시해줍니다.

=GPT_MATCH(A1:A10,B1:B4, 0.8) 을 해주면 유사성이 0.8이상인 셀들의 경우만 결과값을 출력합니다.

GPT_VISION으로 이미지 인식 처리가 가능합니다.

A1에 이미지 주소가 있고 A1 링크의 사진에 대해 설명해보라고 한다면

=GPT_VISION("Write a short description for this product", A1, , , "gpt-4.1") 라고 하면 됩니다.

위 함수들을 직접 Prompt로 서술/설명해서 GPT 함수로 호출할 수도 있습니다.

모든 함수 Documentation

https://gptforwork.com/help/usage/gpt-for-sheets/gpt-functions/all-gpt-functions

All GPT functions in GPT for Sheets | GPT for Work Documentation

All the GPT functions, with simple examples and an extensive list of parameters.

gptforwork.com

이렇듯 모두 기존 스프레드시트 함수보다 한 단계 앞서서 인공지능이 계산을 하고 추론해서 결과값을 가져옵니다.

좀 더 사람이 생각하는 방식과 가깝게 함수를 이용할 수 있습니다.

또한 함수의 인수로 사용되는 값들(대상 Value가 들어 있는 셀이나 영역, 온도, 모델명 등)도 =GPT("prompt", A1, B1, C1)처럼 특정 셀에서 변수처럼 가져올 수 있습니다.

위의 GPT함수기능은

추가기능을 설치하고 추가기능의 권한사용에 동의해야 작동합니다.
실행하는데 약간의 시간이 소요됩니다.
서버 연결이 원활하지 않을 경우 오류가 표시됩니다.
계속 실행하게 되면 요금이 부과될 수 있기 때문에 최초에만 실행됩니다. 문서를 닫아도 결과값이 유지됩니다.
값을 갱신하려면 대상 셀값을 변경하거나 수식을 고치거나 GPT 추가기능에서 Generate 기능을 이용합니다.
데이터를 많이 사용하려면 추가적인 유료 api키가 필요할 수 있습니다.
아직 GPT_IMAGE같은 이미지를 결과값으로 출력하는 함수는 지원하지 않는 걸로 보입니다.
마찬가지로 아직 특정형식의 파일을 결과값으로 출력하는 함수도 지원하지 않습니다.

아래는 모델별 과금 정도나 비용, 기능제약 등에 대한 안내입니다.

비슷한 AI 추가기능들이 많습니다.

AI Assist for Gemini in Sheets

이 Gemini 추가기능은 API 키가 필요합니다.

아래처럼 aistudio.google.com을 방문해서 API키를 복사해서 이 추가기능에 등록해줘야 합니다.

Get API Key를 누르고 API키를 생성하거나 기존에 생성했던 API키를 복사합니다.

추가기능 창을 열거나 확장프로그램 메뉴 > AI Assist for Gemini in Sheets > Set API Key 메뉴에서에서 API키를 등록합니다.

그리고 사용방법은 GPT 함수와 유사합니다.

수식 명령어도 GPT와 유사합니다.

GPT_VISION처럼 이미지 관련 처리도 가능합니다.

=GEM_VISION("Write a short description for this product", A1)

코드 작성도 가능합니다.

=GEM_CODE("Print Hello World in Java.")

맞춤법 편집도 가능합니다.

=GEM_EDIT("For sum reezon thoose nunsberz arnt addin up")

스팸인지 아닌지도 판단해줍니다.

=GEM_SPAM("Your text here")

사용 가능한 수식 Docmentation

https://geminiforwork.gwaddons.com/gemini-for-sheets/gemini-functions/all-available-functions

All available functions | Gemini for Workspace | Gemini AI in Sheets & Docs

Discover all available functions in Gemini for Sheets and Docs, along with simple examples and an extensive list of paramaters.

geminiforwork.gwaddons.com:443

참고로 위 과정을 구글 Apps Script로 코딩해서 구현할 수도 있습니다. 구글 API 키가 필요합니다.

const API_KEY = "여기에_발급받은_GEMINI_API_키를_넣으세요"; 

function GEMINI(prompt) {
  const url = "https://generativelanguage.googleapis.com/v1beta/models/gemini-1.5-flash:generateContent?key=" + API_KEY;
  
  const payload = {
    "contents": [{
      "parts": [{"text": prompt}]
    }]
  };
  
  const options = {
    "method": "post",
    "contentType": "application/json",
    "payload": JSON.stringify(payload)
  };
  
  try {
    const response = UrlFetchApp.fetch(url, options);
    const json = JSON.parse(response.getContentText());
    return json.candidates[0].content.parts[0].text.trim();
  } catch (e) {
    return "Error: " + e.toString();
  }
}

그 다음 시트상에서 Gemini라는 함수를 사용할 수 있습니다.

예를 들어 =GEMINI(B2 & " 단어를 사용한 짧은 예문 1개만 영어로 써줘") 라고 사용하면 됩니다.

ChatGPT를 이용하는 Apps Script 예시 (테스트해보지 않음)

// 여기에 발급받은 OpenAI API 키를 입력하세요
const OPENAI_API_KEY = "sk-여기에_본인의_API_키를_넣으세요"; 

/**
 * 프롬프트를 기반으로 AI 이미지를 생성하고 URL을 반환합니다.
 * @param {string} prompt 이미지 생성 프롬프트
 * @return 이미지 URL
 * @customfunction
 */
function MAKE_IMAGE(prompt) {
  if (prompt == "") return "프롬프트를 입력하세요.";
  
  const url = "https://api.openai.com/v1/images/generations";
  
  const payload = {
    "model": "dall-e-3", // 또는 비용 절감을 위해 "dall-e-2" 사용 가능
    "prompt": prompt,
    "n": 1,
    "size": "1024x1024" // dall-e-2 사용 시 "512x512" 등으로 변경 가능
  };
  
  const options = {
    "method": "post",
    "headers": {
      "Authorization": "Bearer " + OPENAI_API_KEY,
      "Content-Type": "application/json"
    },
    "payload": JSON.stringify(payload),
    "muteHttpExceptions": true
  };
  
  try {
    const response = UrlFetchApp.fetch(url, options);
    const json = JSON.parse(response.getContentText());
    
    if (json.error) {
      return "에러: " + json.error.message;
    }
    
    // 생성된 이미지의 임시 URL 반환
    return json.data[0].url;
  } catch (e) {
    return "요청 실패: " + e.toString();
  }
}

사용방법:

A1 셀: 귀여운 우주인 고양이 그림 그려줘 (프롬프트 입력)
B1 셀: =IMAGE(MAKE_IMAGE(A1))

그리고, AI 추가기능은 위처럼 ai명령 결과를 가져오기도 하고

시트상에서 ai 에게 대신 여러가지 수식 작업을 시키는 것도 가능합니다.

예를 들어 아래처럼 입사날짜만 들어 있을 때 프롬프트를 보내서 자동으로 수식을 만들어 근무경력을 계산하도록 할 수 있습니다.

이상 구글시트상에서 AI명령을 수식으로 호출해서 인공지능 계산 결과를 가져오는 방법을 알아보았습니다.

앞으로는 엑셀이나 구글시트에서도 AI를 적극적으로 활용하게 될 것입니다.

그럴수록 API KEY가 필요하므로 AI서비스에 대한 개인 유료 구독이나 단체 구독 등이 점점 필수가 될 것 같습니다.

Open AI를 창립할 때 누구나 인공지능을 사용할 수 있게 하겠다는 취지로 설립했다고 했지만

전기나 메모리, GPU 등의 자원은 무한하지 않고 한정되어 있는지라

점점 AI를 사용하기 위한 Token이 화폐 혹은 비슷한 기능을 할 수도 있을 것 같습니다.

Token 보유량에 따른 AI 격차/계급화가 우려됩니다.

실시간 도서 ISBN 코드로 재고 수량 조회

쵸코난 — Sat, 7 Mar 2026 23:32:46 +0900

VBA를 이용해서 Http로 서점 서버에 접속해서

시트상에 나열된 ISBN 목록에 대해 각 지점의 재고현황 데이터를 JSON 형식으로 받아서

엑셀 시트에 일괄로 정리하는 사례입니다.

교보문고의 사례입니다. 책 상세 페이지에서 '매장 재고. 위치'를 눌렀을 때 아래와 같이 조회됩니다.

매장 재고 URL은 아래처럼 S000000610612 같은 상품코드를 필요로 합니다.

https://product.kyobobook.co.kr/api/gw/pdt/product/S000000610612/location-inventory

내부 JSON 데이터상에서 saleCmdtid 라는 값인데

ISBN으로 검색하는 상황이므로 바로 상품코드로 조회할 수는 없습니다.

최초에 13자리 ISBN (9788936434120)으로 검색했을 때 내부적인 상품코드인 S000000610612 라는 값을 구해야 합니다.

교보문고는 검색 Input 창에 ISBN 을 입력하면 실시간으로 도서 정보를 가져옵니다.

https://search.kyobobook.co.kr/srp/api/v2/search/autocomplete/shop?keyword=9788936434120

그래서 이렇게 실시간 검색 주소를 이용해서 Json("data")("resultDocuments")(0)("sale_CMDTID") 값을 구하거나

https://www.kyobobook.co.kr/api/gw/aco/search/commodity?keyword=9788936434120&gbCode=TOT&page=1

또는 이렇게 검색해서 Json("data")("resultDocuments")(0)("sale_CMDTID") 값을 구하면 됩니다.

그런데 간혹 1차 실시간 JSON 데이터로는 검색이 되지 않지만 결과가 넘어오는 경우가 있는데 그때는 HTML 문서에서 찾아와야 합니다.

https://search.kyobobook.co.kr/search?keyword=9788936434120&gbCode=TOT&target=total

위 처럼 접속해서 HTML 문서 상에 검색된 도서중에서 prod_item 목록 중 input 태그의 data-pid 속성값에 S000000610612 을 구할 수 있습니다. 물론 표지 이미지 파일명에서 가져올 수도 있습니다.

이제 최종적으로 https://product.kyobobook.co.kr/api/gw/pdt/product/S000000610612/location-inventory 이런 주소로 접속해서 매장별 재고 숫자를 가져옵니다.

접속해서 받아온 JSON 데이터에서 Json("data")("list")의 배열 데이터중에서 각 배열 데이터내의

strName 은 매장위치이고 realInvnQntt 는 재고 수량이 되겠습니다.

위 과정에 대한 VBA 코드는 아래와 같습니다.

Option Explicit

Dim http As Object  'New MSXML2.ServerXMLHTTP60
Dim html As New MSHTML.HTMLDocument '도구 > 참조 : Microsoft HTML Object Library 체크 필요
Dim Json As New JsonBag, itm As New JsonBag, lst As New JsonBag

Sub getKyobo()

    Dim sht As Worksheet
    Dim lastrow As Long, lastcol As Long, l As Long
    Dim rng As Range, irng As Range
    Dim ret As Long
    
    Set sht = ActiveSheet
    lastrow = sht.Cells(sht.Rows.Count, "A").End(xlUp).Row
    If lastrow < 2 Then Exit Sub
    lastcol = sht.Cells(1, sht.Columns.Count).End(xlToLeft).Column
    If lastcol < 2 Then Exit Sub
    
    'Application.ScreenUpdating = False
    Set http = CreateObject("MSXML2.ServerXMLHttp")
    If html Is Nothing Then MsgBox "Alt+F11창에서 도구>참조> Microsoft HTML Object Library에 체크하세요.": Exit Sub
    
    On Error Resume Next
    For Each rng In sht.Range("A2:A" & lastrow)
        rng.NumberFormat = "@"
        If Not ValidateISBN(rng.Value) Then
            rng.Font.Color = rgbRed
        Else
            rng.Hyperlinks.Delete
            rng.Offset(, 1).Resize(1, lastcol).Clear
            Call getKyoBobooks(rng)
            l = l + 1
            Application.StatusBar = "Processing : " & l & " / " & lastrow - 1
            If l Mod 5 = 0 Then Application.Wait (Now + TimeSerial(0, 0, 1))
        End If
        rng.HorizontalAlignment = Excel.Constants.xlCenter
    Next rng
    Application.ScreenUpdating = True
    Set http = Nothing
    Set html = Nothing
    Application.StatusBar = False
End Sub

Private Sub test()
    Set http = CreateObject("MSXML2.ServerXMLHttp")
    Debug.Print getKyoBobooks(ActiveCell)
 
    Set http = Nothing
End Sub

Function getKyoBobooks(ISBN As Range) As Long
    
    Dim url As String, arr() As String
    Dim Loc As Range
    Dim oSht As Worksheet
    Dim lastcol As Integer, l As Integer, I As Integer
    Dim SaleCode As String, temp As String
    
    Set oSht = ISBN.Parent
    lastcol = oSht.Cells(1, oSht.Columns.Count).End(xlToLeft).Column
    
    'sale_CCMDTID
        'https://www.kyobobook.co.kr/api/gw/aco/search/commodity?keyword=9788954682152&gbCode=TOT&page=1
    '    {
    '    "data": {
    '    "returnCode": 1,
    '    "errorMessage": null,
    '    "resultDocuments": [
    '      {
    '        "chrc_NAME": "한강",
    '        "sale_CMDT_DVSN_CODE": "KOR",
    '        "cmdtcode": "9788954682152",
    '        "pbcm_NAME": "문학동네",
    '        "sale_CMDT_PRCE": "16800",
    '        "img_URL": "https://contents.kyobobook.co.kr/sih/fit-in/200x0/pdt/9788954682152.jpg",
    '        "sale_CMDTID": "S000000781116",
    '        "cmdt_NAME": "작별하지 않는다",
    '        "score": "102312",

    'URL = "https://search.kyobobook.co.kr/srp/api/v1/search/autocomplete/shop?callback=autocompleteShop&keyword=" & ISBN.Text
    url = "https://www.kyobobook.co.kr/api/gw/aco/search/commodity?keyword=" & ISBN.Text & "&gbCode=TOT&page=1"
    'URL = "https://www.kyobobook.co.kr/api/gw/aco/search/commodity?keyword=" & ISBN.Text & "&gbCode=kyobo&page=1"
    'Debug.Print URL
    
    With http
            .Open "GET", url, False
            .setRequestHeader "User-Agent", "Mozilla/5.0 (Windows NT 10.0; Win64; x64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/127.0.0.0 Safari/537.36"       '"Mobile"
            '.setRequestHeader "Content-Type", "Application / javascript"
            .send
            temp = .responseText
            Json.Json = temp
            'Debug.Print temp
    End With
    
    '검색되지 않은 경우 HTML 검색
    If Json("data")("resultDocuments").Count < 1 Then
        url = "https://search.kyobobook.co.kr/search?keyword=" & ISBN.Text & "&gbCode=TOT&target=total"
        With http
            .Open "GET", url, False
            .setRequestHeader "User-Agent", "Mozilla/5.0 (Windows NT 10.0; Win64; x64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/127.0.0.0 Safari/537.36"       '"Mobile"
            '.setRequestHeader "Content-Type", "Application / javascript"
            .send
            temp = .responseText
            html.body.innerHTML = temp
            'Debug.Print temp
        End With
        
        SaleCode = ""
        On Error Resume Next
        SaleCode = html.querySelector(".prod_item > span > input").getAttribute("data-pid")
        On Error GoTo 0
        'Debug.Print ISBN, SaleCode
        
        If Len(SaleCode) > 0 Then
            ISBN.Hyperlinks.Add ISBN, Address:="https://product.kyobobook.co.kr/detail/" & SaleCode, ScreenTip:="▶ ISBN Found >> but no data"
            ISBN.Font.Color = rgbBlue
        Else
            ISBN.Hyperlinks.Add ISBN, Address:="https://www.google.co.kr/search?hl=ko&tbo=p&tbm=bks&q=isbn:" & ISBN, _
                ScreenTip:="▶ ISBN Not found" & " >> Search on Google"
            ISBN.Font.Color = rgbDarkOrange
            'Debug.Print "Not found : " & ISBN.Text
            getKyoBobooks = -1: Exit Function
        End If
    Else
        SaleCode = Json("data")("resultDocuments")(1)("sale_CMDTID")
        'Debug.Print SaleCode
        '요약 문자열 분리
        temp = Json("data")("resultDocuments")(1)("cmdt_NAME")
        temp = temp & ", " & Json("data")("resultDocuments")(1)("chrc_NAME")
        temp = temp & ", " & Json("data")("resultDocuments")(1)("sale_CMDT_PRCE")
        ISBN.Hyperlinks.Add ISBN, Address:="https://product.kyobobook.co.kr/detail/" & SaleCode, _
            ScreenTip:=temp
        
    End If
        
   
    
    url = "https://product.kyobobook.co.kr/api/gw/pdt/product/" & SaleCode & "/location-inventory"
   'Debug.Print URL
    With http
        .Open "GET", url, False
        .setRequestHeader "Accept", "application/json, text/plain, */*"
        .setRequestHeader "Content-Type", "application/json"
        .setRequestHeader "User-agent", "Mozilla/5.0"
        .send
        '{
        '    "data": [
        '        {
        '            "strAreaGrpCode": "001",
        '            "list": [
        '                {
        '                    "barcode": "9791169092753",
        '                    "saleCmdtId": "S000213845355",
        '                    "saleCmdtGrpDvsnCode": "SGK",
        '                    "saleCmdtDvsnCode": "KOR",
        '                    "strRdpCode": "001",
        '                    "strName": "광화문",
        '                    "strAreaGrpCode": "001",
        '                    "strAdrs": "서울특별시 종로구 종로 1, 교보생명빌딩 지하 1층",
        '                    "strTlnm": "02-397-3400",
        '                    "realInvnQntt": 85,
        '                    "dlvrRqrmDyCont": 0,
        '                    "plorRqrmDyCont": 0
        '                },
         Json.Json = .responseText
    End With
    
    If Json("data").Count = 0 Then getKyoBobooks = -1: Exit Function

    'Debug.Print Json.Json
    '처음인 경우 지점 목록 출력
    If ISBN.Row = 2 Then
        For Each lst In Json("data")
            For Each itm In lst("list")
                I = I + 1
                oSht.Range("A1").Offset(, I) = itm("strName")
            Next itm
        Next lst
        lastcol = oSht.Cells(1, oSht.Columns.Count).End(xlToLeft).Column
    End If
    
    '지점별 검색
    For Each Loc In oSht.Range("B1", oSht.Cells(1, lastcol))
        For Each lst In Json("data")
            For Each itm In lst("list")
                If itm("strName") = Loc Then
                    oSht.Cells(ISBN.Row, Loc.Column) = itm("realInvnQntt") '지점이름과 같으면 재고 현황 입력
                End If
            Next itm
        Next lst
    Next Loc

    
End Function

아래와 같이 주어진 ISBN 코드에 대한 각 매장별 재고 수량을 조회할 수 있습니다.

서버에 부담을 줄이기 위해 몇초마다 대기 시간을 주는 것이 좋겠습니다.

대량의 도서에 대한 검색은 정식 API를 이용해서 검색하거나 매장의 검색 시스템을 이용하는 것을 권장합니다.

이번에는 영풍문고 사례입니다.

ISBN 검색해서 상세 페이지로 이동 후 '매장 재고 및 위치 확인'을 눌러서 확인 합니다.

https://www.ypbooks.co.kr/back_shop/base_shop/api/v1/product/stock-info?iBookCd=100507073&iNorPrc=15000&iGubun=n

이렇게 JSON 데이터를 받아와야 하는데 iBookCd 값과 iNorPrc 가격 값이 필요합니다.

내부적인 상품코드가 필요합니다.

영풍문고도 검색 Input 란에 ISBN을 입력할 때 실시간으로 아래와 같은 도서 정보를 불러옵니다.

https://www.ypbooks.co.kr/back_shop/base_shop/api/v1/search_indexes/result/product?type=product&collection=yp_product&nationType=korea%2Cjapan%2Cwestern%2Cstationerygift&query=9788936434120&listCount=3&pageNumber=1&startDate=1970.01.02&endType=1%2C2%2C3%2C4%2C5%2C7&autoDiv=true&searchType=ON&target=ark

하지만 위 주소로 그냥 접속하면 아래처럼 JSON데이터가 돌아오지 않고 JSON 데이터 속에는 FAIL 값만 돌아옵니다.

좀 더 살펴보니 접속할 때 Guestaccesstoken 이라는 값이 없는 경우 FAIL 값을 돌려주고 있습니다.

일단은 VBA에서 HTTP 접속할 때 RequestHeader 에 넣어주면 되는데

저 값은 접속하는 세션과 시간에 따라 달라집니다.

다행히 모바일로 접속할 때 AccessToken 값을 구할 수 있습니다.

https://m.ypbooks.co.kr/back_login/base_login/api/v1/auth/login-guest

먼저 login-guest로 접속해서 돌아온 JSON 데이터에서 Json("data")("accessToken") 값으로 토큰 값을 구한 다음

https://www.ypbooks.co.kr/back_shop/base_shop/api/v1/search_indexes/result/product?type=product&collection=yp_product&nationType=korea%2Cjapan%2Cwestern%2Cstationerygift&query=978893643412~~~ 로 접속할 때 RequestHeader 의 Guestaccesstoken 값과 함께 접속합니다.

Json("data")("ypProductResult")("dataList") 의 첫번째 배열값에서 "bookCd" 값이나 ProductIdCd 값으로 부터 100507073 이라는 내부 상품코드를 구할 수 있습니다. productPrice 값에서 가격을 알 수 있습니다.

이제 매장별 재고를 알아내기 위해 다음 주소로 접속합니다.

https://m.ypbooks.co.kr/back_shop/base_shop/api/v1/product/stock-info?iBookCd=100507073&iNorPrc=15000&iGubun=y

Json("data") 의 각 배열 속의 "labst" 값에서 매장별 재고 수량을 가져옵니다.

아래 그림처럼 주어진 ISBN 코드로 검색해서 매장별 수량을 일괄로 파악할 수 있습니다.

영풍문고 검색 VBA코드는 아래와 같습니다.

Option Explicit

Dim http As Object  'New MSXML2.ServerXMLHTTP60
Dim Json As New JsonBag, itm As New JsonBag
Dim sToken As String

Sub getYP()

    Dim sht As Worksheet
    Dim lastrow As Long, lastcol As Long, l As Long
    Dim rng As Range, irng As Range
    Dim ret As Long
    
    Set sht = ActiveSheet
    lastrow = sht.Cells(sht.Rows.Count, "A").End(xlUp).Row
    If lastrow < 2 Then Exit Sub
    lastcol = sht.Cells(1, sht.Columns.Count).End(xlToLeft).Column
    If lastcol < 2 Then Exit Sub
    
    'Application.ScreenUpdating = False
    Set http = CreateObject("MSXML2.XMLHttp")
    sToken = getToken
    If sToken = "" Then MsgBox "Getting GuestAccessToken Failed": Exit Sub
    
    On Error Resume Next
    For Each rng In sht.Range("A2:A" & lastrow)
        'If Len(Trim(rng.Text)) = 13 Then
        rng.Hyperlinks.Delete
        rng.Offset(, 1).Resize(1, lastcol).Clear
        Call getYPbooks(rng)
        l = l + 1
        Application.StatusBar = "Processing : " & l & " / " & lastrow
        If l Mod 5 = 0 Then Application.Wait (Now + TimeSerial(0, 0, 1))
        'End If
    Next rng
    Application.ScreenUpdating = True
    Set http = Nothing
    Application.StatusBar = False
End Sub

Private Sub test()
    Set http = CreateObject("MSXML2.ServerXMLHttp")
    Debug.Print getYPbooks(Range("A5"))
 
    Set http = Nothing
End Sub

Function getYPbooks(ISBN As Range) As Long
    
    Dim url As String, bookUrl As String, bookCd As String, price As String
    Dim Loc As Range
    Dim oSht As Worksheet
    Dim lastcol As Integer, I As Integer
  
    Set oSht = ISBN.Parent
    lastcol = oSht.Cells(1, oSht.Columns.Count).End(xlToLeft).Column
    
    'https://m.ypbooks.co.kr/back_shop/base_shop/api/v1/search_indexes/result/product?type=product&collection=yp_product&introSearchField=&listCount=10&pageNumber=1&query=9788972918349&reQuery=&sort=RANK&sortOrder=DESC&startDate=1970.01.02&endDate=&themeType=ALL&rtField=&avgValuation=
    url = "https://m.ypbooks.co.kr/back_shop/base_shop/api/v1/search_indexes/result/product?type=product&collection=yp_product&listCount=10&pageNumber=1&query=" & Trim(ISBN.Text)
    With http
        'Debug.Print URL
        .Open "GET", url, False
        .setRequestHeader "Accept", "application/json, text/plain, */*"
        .setRequestHeader "Content-Type", "application/json"
        .setRequestHeader "User-agent", "Mozilla/5.0"
        .setRequestHeader "Guestaccesstoken", sToken '"30695cefcc1d8e05be56f8ee511218e1"
        .send
        
        Json.Json = .responseText
        'Debug.Print Json.Json
        '  "state": "SUCCESS",
        '  "stateCode": 200,
        '  "data": {
        '  "ypProductResult": {
        '      "count": 1,
        '      "totalCount": 1,
        '      "dataList": [
        '        {
        '          "docid": "202406106586248084",
        '          "cdCtgyNm": [
        '            "인문",
        '            "세계역사/지리"
        '          ],
        '          "salePrice": 19800,
        '          "recoValuation": 14213,
        '          "productCd": "202406106586248084",
        '          "productIdCd": "9788972918349",
        '          "productName": "노마드 - 문명을 가로지른 방랑자들 유목민이 만든 절반의 역사",
        '          "writerName": [
        '            "앤서니 새틴"
        '          ],
        '          "translatorName": [
        '            "이순호"
        '          ],
        '          "pubCompanyName": "까치글방",
        '          "productPrice": "22000",
        '          "categoryIds": [
        '            "659"
        '          ],
        '          "productReviewCount": "0",
        '          "bookImgPath": "/image/product/202406",
        '          "keywords": "[\"유목민\",\"세계사\",\"인류사\",\"유전자\",\"역사\",\"방랑자\"]",
        '          "clickCnt": "1149",
        '          "bookImgName": "0622cfd1-1de7-46aa-a976-d4790e946d5c.jpg",
        '{"state":"SUCCESS","stateCode":200,"msg":null,
        '"data":{"message":null,"retCode":0,"totalCount":0,"searchRequest":
        '{"reQuery":"","rtfield":null,"endDate":"2029.07.07","message":"","query":"9788954737517","collection":"yp_product","listCount":10,"pageNumber":1,"startDate":"1970.01.01","sort":"RANK","sortOrder":"DESC","nationType":"","cateCode":"","themeType":"","prefix":"","startPrice":-1,"endPrice":-1,"introSearchField":"","revValuation":-1,"eventStatus":"","success":true,"productPrice":"","endType":"-1"},"ypProductResult":{"count":0,"totalCount":0,"dataList":[],"categoryList":[],"nationList":[{"nationName":"korea","nationCount":0},{"nationName":"japan","nationCount":0},{"nationName":"western","nationCount":0}],"categoryAllList":[],"arkList":null,"deliveryConditionList":null},"ypProductIntroResult":null,"ypProductReviewResult":null,"ypThemeResult":null,"ypEventResult":null,"ypFaqResult":null},"confirm":false}

        
        'If Json("state") Like "FAIL" Then getYPbooks = -1: Exit Function
        If Json("data")("ypProductResult")("totalCount") < 1 Then
            Debug.Print "Result 0 : " & ISBN.Text
            getYPbooks = -1: Exit Function
        End If
        
        Set itm = Json("data")("ypProductResult")("dataList")(1)
        bookUrl = "https://m.ypbooks.co.kr/bookDetail/" & itm("productCd")
        ISBN.Hyperlinks.Add ISBN, bookUrl, , itm("productName") & vbNewLine & itm("writerName")(1) & vbNewLine & Format(itm("salePrice"), "###,###,##0")
        bookCd = itm("bookCd")
        price = itm("productPrice")
        If bookCd = "" Or price = "" Then getYPbooks = -1: Exit Function
    End With
    
    'Debug.Print bookCd, price
    'https://m.ypbooks.co.kr/back_shop/base_shop/api/v1/product/stock-info?iBookCd=101298565&iNorPrc=22000&iGubun=y
    url = "https://m.ypbooks.co.kr/back_shop/base_shop/api/v1/product/stock-info?iBookCd=" & bookCd & "&iNorPrc=" & price & "&iGubun=y"
    'Debug.Print URL
    With http
        .Open "GET", url, False
        .setRequestHeader "Accept", "application/json, text/plain, */*"
        .setRequestHeader "Content-Type", "application/json"
        .setRequestHeader "User-agent", "Mozilla/5.0"
        .send
        '{
        '    "state": "SUCCESS",
        '    "stateCode": 200,
        '    "msg": null,
        '    "data": [
        '        {
        '            "werks": "4900",
        '            "werksNm": "가산마리오",
        '            "labst": 1,
        '            "regio": "",
        '            "rezei": "",
        '            "zsort": ""
        '        },
        Json.Json = .responseText
    End With
    
    If Json("state") Like "FAIL" Then getYPbooks = -1: Exit Function

    'Debug.Print Json.Json
    '각 지점 data 순환
    For Each itm In Json("data")
        'Debug.Print itm("werksNm") & ",";
        '지점별 검색
        For Each Loc In oSht.Range("B1", oSht.Cells(1, lastcol))
            If itm("werksNm") = Loc Then
                oSht.Cells(ISBN.Row, Loc.Column) = itm("labst") '지점이름과 같으면 재고 현황 입력
            End If
        Next Loc
    Next itm
    ISBN.HorizontalAlignment = xlCenter
End Function

Function getToken() As String
 

    Dim http As Object
    Dim cookie As String
    
    Set http = CreateObject("MSXML2.ServerXMLHTTP")

    With http
        .Open "PUT", "https://m.ypbooks.co.kr/back_login/base_login/api/v1/auth/login-guest", False
        .setRequestHeader "Accept", "application/json, text/plain, */*"
        .setRequestHeader "Referer", "https://m.ypbooks.co.kr/search_result"
        .setRequestHeader "User-agent", "Mozilla/5.0"
        .send
        
        'Application.Wait Now + TimeSerial(0, 0, 1)
        'cookie = .getResponseHeader("Set-Cookie")
        'Debug.Print .getAllResponseHeaders
        Json.Json = .responseText
        
        If Json("state") Like "FAIL" Then Exit Function
        getToken = Json("data")("accessToken")
        
    End With
    'Set http = Nothing
End Function

마찬가지로 서버에 부담을 줄이기 위해 몇초마다 대기 시간을 주는 것이 좋겠습니다.

또한 대량의 도서에 대한 검색은 정식 API를 이용해서 검색하거나 매장의 검색 시스템을 이용하는 것을 권장합니다.

샘플 파일을 첨부합니다.

무분별한 사용을 방지하기 위해 VBA코드에는 암호가 걸려 있습니다.

교보영풍등_재고검색1.xlsm

0.14MB

Picture generated by Gemini

멜론 노래 정보 가져와서 음악파일명 일괄 변경하기

쵸코난 — Mon, 2 Mar 2026 17:04:12 +0900

QuerySelector를 이용한 다음(DAUM) 뉴스 검색

모바일 다음에서 뉴스기사를 검색하면 아래와 같은 URL로 접속됩니다.https://m.search.daum.net/search?w=news&q=인공지능최대한 간단히 줄인 주소입니다.PC웹에서 검색해도 비슷한데 효율성을 위해서 모바

konahn.tistory.com

이번에는 멜론 사이트의 노래 순위, 제목, 가수, 앨범 아트 정보를 가져옵니다.

일단 상황은 미리 멜론, 벅스, 스포티파이 등 음악사이트에서 다운 받아놓은 mp3 등의 파일의 파일명을

내가 원하는 스타일로 일괄로 바꾸고 싶은 경우입니다.

001.mp3 ▶️▶️ 001. IVE (아이브) - BANG BANG.mp3

위와 같이 바꾸고 싶습니다.

한 두개가 아니라 100여곡이 된다면 일일이 바꾸는 것이 만만치 않습니다.

멜론 사이트에서 곡 정보를 받아와서 엑셀에 정리하고

지난 번 파일명 변경 매크로로 일괄 변경하는 것이 목표입니다.

멜론의 곡 순위는 아래와 같은 주소에서 가져올 수 있습니다.

    ' url = "https://www.melon.com/chart/search/list.htm?chartType=WE&age=2020&year=2026&mon=01&day=20260126%5E20260201&classCd=GN0000&startDay=20260126&endDay=20260201&moved=Y"
    ' url = "https://www.melon.com/chart/week/index.htm?classCd=GN0000&moved=Y&startDay=20260126&endDay=20260201"
     'url = "https://www.melon.com/chart/week/index.htm?classCd=DM0000&moved=Y&startDay=20260126&endDay=20260201"
    ' url = "https://www.melon.com/chart/day/index.htm?classCd=GN0000"
    ' url = "https://www.melon.com/chart/search/list.htm?chartType=WE&classCd=GN0000&startDay=20260126&endDay=20260201&moved=Y"

index.htm은 TOP100 등의 순위를 가져오고

차트 파인더로 과거 정보를 검색해 올 때는 list.htm 으로 가져옵니다.

list.htm 은 단순히 테이블 형태의 자료입니다.

50위까지는 보이는데 나머지 50개는 display:none 으로 숨긴 채로 가져옵니다.

여기서는 일간 TOP100 을 기준으로 하겠습니다.

노래 한 곡의 정보는 Class 이름이 lst50 이거나 lst100 이라는 TR 요소 안에 들어 있습니다.

<tr class="lst50" id="lst50"  data-song-no="601237102">

	<td><div class="wrap t_right"><input type="checkbox" title="BANG BANG 곡 선택" class="input_check "  name="input_check" value="601237102"></div></td>
	<td><div class="wrap t_center"><span class="rank ">1</span><span class="none">위</span></div></td>

		<!-- 차트순위 추가 -->
		<td><div class="wrap">순위...</div></td>

	<td><div class="wrap">
		<a href="/album/detail.htm?albumId=12845274" title="REVIVE+" class="image_typeAll">
			<img onerror="WEBPOCIMG.defaultAlbumImg(this);" width="60" height="60" src="https://cdnimg.melon.co.kr/cm2/album/images/128/45/274/12845274_20260223113048_500.jpg/melon/resize/120/quality/80/optimize" alt="REVIVE+ - 페이지 이동"/>
			<span class="bg_album_frame"></span>
		</a>
	</div></td>
	<td><div class="wrap">
		<a href="/song/detail.htm?songId=601237102" title="BANG BANG 곡정보" class="btn button_icons type03 song_info"><span class="none">곡정보</span></a>
	</div></td>
	<td><div class="wrap">
		<div class="wrap_song_info">
			<div class="ellipsis rank01"><span>
				<a href="javascript:melon.play.playSong('1000002721',601237102);" title="BANG BANG 재생">BANG BANG</a>
			</span></div><br>
			<div class="ellipsis rank02">
				<a href="/artist/timeline.htm?artistId=3055146" title="IVE (아이브) - 페이지 이동">IVE (아이브)</a><span class="checkEllipsis" style="display:none"><a href="/artist/timeline.htm?artistId=3055146" title="IVE (아이브) - 페이지 이동">IVE (아이브)</a></span>
			</div>
			
		</div>
	</div></td>
	<td><div class="wrap">
		<div class="wrap_song_info">
			<div class="ellipsis rank03">
				<a href="/album/detail.htm?albumId=12845274" title="REVIVE+ - 페이지 이동">REVIVE+</a>
			</div>
		</div>
	</div></td>
	<td><div class="wrap">
		<button type="button" class="button_etc like" title="BANG BANG 좋아요" data-song-no="601237102" data-song-menuid="1000002721">
			<span class="odd_span">좋아요</span>
			<span class="cnt">
				<span class="none">총건수</span>
				0
			</span>
		</button>
	</div></td>
	<td><div class="wrap t_center"> 버튼들...</div></td>
</tr>

우리가 필요한 것은 순위, 노래제목, 가수, 앨범아트 입니다.

먼저 winhttp 나 xmlhttp등의 http로 접속해서 HTML문서인 htmlDoc을 받아옵니다.

getelementsbyClassname 도 가능하지만 여기서는 querySelector를 이용해보겠습니다.

querySelectorAll(".lst50, .lst100") 으로 가져오면 클래스 이름이 lst50이거나 lst100 인 모든 요소를 가져올 수 있습니다.

.lst50 라고 쓰면 클래스 이름이고 #lst50 이면 ID, 그냥 lst50 이라고 쓰면 태그로 인식합니다.

이렇게 하면 lst50이나 lst100인 TR 하위 요소 전체를 한 덩어리로 가져올 수 있습니다.

여기서 다시 .querySelector("rank").innerText 를 이용해서 rank 라는 클래스 이름에서 순위를 구합니다.

.querySelector("rank01").innerText 를 이용해서 rank01 라는 클래스 이름에서 노래제목을 구합니다.

.querySelector("rank02").innerText 를 이용하면 가수이름이 2번 나오기 때문에

.querySelector("rank02 > a").innerText 를 이용해서 첫번째 a 태그 안의 가수이름을 한 번만 가져옵니다.

rank03은 앨범 정보이므로 넘어가도록 합니다.

앨범아트 이미지는 .querySelector("img").src 로 가져올 수 있습니다.

앨범아트를 클릭했을 때 이동할 노래 정보 페이지는 .getAttribute("data-song-no") 로 601237102 과 같은 노래의 고유 아이디를 가져올 수 있습니다. https://www.melon.com/song/detail.htm?songId= 이 뒤에 노래 아이디를 붙여서 링크시키면 됩니다.

마지막으로 새로운 파일명 규칙이 순위. 가수 - 노래 제목.mp3 와 같은 식이라면

오른쪽 셀에 = Format(A2, "000") & ". " & C2 & " - " & B2 와 같은 함수식을 추가하도록 합니다.

아래는 현재 시트에 멜론 TOP100 정보를 가져오는 전체 코드입니다.

주) 사이트가 변경되면 언제라도 아래 코드는 작동하지 않습니다.

Option Explicit

Sub getTop100()
    
    Dim wb As Workbook
    Dim htmlContent As String
    Dim htmlDoc As New MSHTML.HTMLDocument
    Dim rowItems As IHTMLDOMChildrenCollection  'Object
    Dim item As Object  'IHTMLElement    'Object
    Dim i As Long
    
    '   'HTML 파일로 읽을 경우
    '    Dim filePath As String, fileNo As Integer, lineText As String
    '    filePath = ThisWorkbook.Path & "\1.html"
    '    fileNo = FreeFile
    '    Open filePath For Input As #fileNo
    '        Do Until EOF(fileNo)
    '            Line Input #fileNo, lineText
    '            htmlContent = htmlContent & Trim(lineText) & vbCrLf
    '        Loop
    '    Close #fileNo
    
    Dim http As Object
    Dim url As String, slink As String
    
   ' 1. 대상 URL 설정
    ' url = "https://www.melon.com/chart/search/list.htm?chartType=WE&age=2020&year=2026&mon=01&day=20260126%5E20260201&classCd=GN0000&startDay=20260126&endDay=20260201&moved=Y"
    ' url = "https://www.melon.com/chart/week/index.htm?classCd=GN0000&moved=Y&startDay=20260126&endDay=20260201"
     'url = "https://www.melon.com/chart/week/index.htm?classCd=DM0000&moved=Y&startDay=20260126&endDay=20260201"
    url = "https://www.melon.com/chart/day/index.htm?classCd=GN0000"
    ' url = "https://www.melon.com/chart/search/list.htm?chartType=WE&classCd=GN0000&startDay=20260126&endDay=20260201&moved=Y"
    slink = "https://www.melon.com/song/detail.htm?songId="
    
    ' 2. ServerXMLHTTP 객체 생성 및 요청
    Set http = CreateObject("MSXML2.ServerXMLHTTP")
    
    With http
        .Open "GET", url, False
        .setRequestHeader "User-Agent", "Mozilla/5.0 (Windows NT 10.0; Win64; x64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/120.0.0.0 Safari/537.36"
        '.setRequestHeader "accept", "text/html,application/xhtml+xml,application/xml;q=0.9,image/avif,image/webp,image/apng,*/*;q=0.8,application/signed-exchange;v=b3;q=0.7"
        '.setRequestHeader "Host", "www.melon.com"
        .send
        
        If .Status <> 200 Then MsgBox "페이지 접속에 실패했습니다. 에러 코드: " & .Status: Exit Sub
    ' 3. HTML 파싱 (Microsoft HTML Object Library 참조 필요)
        htmlDoc.body.innerHTML = .responseText
    End With
    
    ' 4. querySelectorAll로 .lst50 탐색
    Set rowItems = htmlDoc.querySelectorAll(".lst50, .lst100 ")
    If rowItems Is Nothing Then MsgBox ".lst50 or .lst100 fetching failed": Exit Sub
    'MsgBox rowItems.Length
    
    ' 5. 결과 출력
    Dim ws As Worksheet: Set ws = ActiveSheet: Set wb = ws.Parent
    ws.Cells.Clear: ws.Hyperlinks.Delete
    For i = ws.Shapes.Count To 1 Step -1: If ws.Shapes(i).Name Like "Img_*" Then ws.Shapes(i).Delete
    Next i
    ws.Range("A1:E1").Value = Array("Rank", "제목", "가수", "파일명", "앨범아트")
    
    'i = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row + 1
    'On Error Resume Next
    'For each item in rowItems 는 순환 후 강제종료 오류발생
    For i = 0 To rowItems.Length - 1
        
        ' 각 항목 하위의 rank01, rank02 텍스트 추출
        ws.Cells(i + 2, 1).Value = i + 1
        If Not rowItems(i).querySelector(".rank01") Is Nothing Then
            ws.Cells(i + 2, 2).Value = rowItems(i).querySelector(".rank01").innerText
        End If
        
        If Not rowItems(i).querySelector(".rank02 a") Is Nothing Then
            ws.Cells(i + 2, 3).Value = rowItems(i).querySelector(".rank02 > a").innerText
        End If
        '파일명
        ws.Cells(i + 2, 4).Formula = "=TEXT(A" & i + 2 & ",""000"") & "". "" & C" & i + 2 & " & "" - "" & B" & i + 2
                
        '앨범이미지
        If Not rowItems(i).querySelector("img") Is Nothing Then
            'Debug.Print rowItems(i).querySelector(".input_check").Value, rowItems(i).getAttribute("data-song-no")
            With ws.Cells(i + 2, 5)
                Dim shp As Shape
                .EntireRow.RowHeight = 45
                .EntireColumn.ColumnWidth = 8
                Set shp = ws.Shapes.AddPicture(rowItems(i).querySelector("img").src, msoFalse, msoTrue, .Left, .Top, .Width, .Height)
                shp.Name = "Img_" & ws.Cells(i + 2, 4).Value
                ws.Hyperlinks.Add Anchor:=shp, Address:=slink & rowItems(i).getAttribute("data-song-no") 'querySelector(".input_check").Value
            End With
        End If
        
        If i = 99 Then wb.Save

    Next i
 
    Cells.Columns.AutoFit
    Set htmlDoc = Nothing
    Set http = Nothing
    
    'MsgBox "완료!"
End Sub

위 매크로 실행 결과 아래와 같이 나만의 방식대로 각 노래의 파일명이 완성되었습니다.

참고로 앨범 아트도 보여주고 클릭하면 구체적인 노래 정보 사이트로 연결됩니다.

이제 파일명 변경 매크로를 이용합니다.

이전 파일명이 001.mp3 였는데 폴더의 mp3 파일들을 불러와서 C열에 = Sheet2!D2 와 같은 함수식을 써주고

Rename Files 를 실행하면 일괄로 "001. IVE (아이브) - BANG BANG.mp3" 로 바뀌게 됩니다.

샘플 매크로 파일 첨부합니다.

Sheet2에서 멜론 노래 정보를 가져오고

(멜론의 어떤 순위인지에 따라 url 주소를 미리 변경해야 합니다.)

Sheet1에서 기존 파일 목록을 불러와서 C열에 =Sheet2.D2와 같은 함수식을 적용하고

RenameFiles를 누르면 파일명을 일괄 변경합니다.

RenameFiles_Melon1.xlsm

0.49MB

파일명에 쓸 수 없는 문자를 검사하는 부분을 추가할 수도 있겠습니다.

' 파일명으로 쓸 수 없는 문자 (\ / : * ? " < > |) 제거 함수
Function CleanFileName(str As String) As String
    Dim i As Integer
    Dim illegalChars As String
    illegalChars = "\/:*?""<>|"
    CleanFileName = str
    For i = 1 To Len(illegalChars)
        CleanFileName = Replace(CleanFileName, Mid(illegalChars, i, 1), "")
    Next i
End Function

Image by Gemini

파워포인트 원하는 편집 슬라이드로 바로 이동

쵸코난 — Tue, 27 Jan 2026 17:24:36 +0900

관련: 지식인

파워포인트 슬라이드 쇼에서는 숫자 누르고 엔터를 치면 해당 숫자 슬라이드로 이동하지만

편집 상태에서는 이러한 기능을 지원하지 않습니다.

지원하지 않지만 종종 요구되는 기능이기도 합니다.

VBA로도 일반 편집 모드에서 키보드 숫자에 반응하기 어렵습니다.

이럴 때 AutoHotkey를 이용하는 것이 효율적입니다.

첨부한 Jump2Slide.exe 를 다운받아 실행하세요.

여기서 확인을 누릅니다. 상태표시줄로 최소화됩니다.

이제 파워포인트 슬라이드 편집창에서

Ctrl을 누른 채로 원하는 슬라이드 번호 숫자를 누르고 Ctrl 키를 뗍니다.

Ctrl에서 손을 떼는 순간 해당 슬라이드로 바로 이동합니다.

예를 들어 1슬라이드 편집하다가 Ctrl+3을 누르면 Ctrl 을 떼는 순간 3슬라이드로 바로 이동합니다.

한 자리 수뿐만 아니라 그 이상도 가능합니다.

Ctrl을 누르고 13을 입력하고 Ctrl 을 떼면 13 슬라이드로 이동합니다.

Ctrl+x를 누르면 단축키 프로그램은 종료합니다.

상태표시줄의 별모양 아이콘을 우클릭 후 종료해도 됩니다.

조건:

파워포인트 일반 슬라이드 편집 모드일때만 작동합니다.
슬라이드쇼나 슬라이드마스터 보기 등에서는 작동하지 않습니다.
입력한 숫자가 슬라이드 범위를 벗어나면 오류창이 뜹니다.

아래는 오토핫키 코드(v1)입니다.

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.


	msgbox,64,Jump2Slide, Press <Ctrl-#> to jump to the PPT slide in the normal view. <Ctrl+x> to quit.
	;Menu, Tray, Icon, shell32.dll, 322
    if (%A_IsCompiled%)  {
		Menu, Tray, Icon, %A_ScriptName%, 1
	}
	Menu, Tray, Tip, <Ctrl-#> to jump to the PPT slide. <Ctrl+x> to quit.
	Menu, Tray, NoStandard
	Menu, Tray, Add, Exit, ExitMenu
return

Nums := ""

#IfWinActive ahk_class PPTFrameClass

; 숫자 0~9 및 숫자패드 대응
~^0::Nums .= "0"
~^1::Nums .= "1"
~^2::Nums .= "2"
~^3::Nums .= "3"
~^4::Nums .= "4"
~^5::Nums .= "5"
~^6::Nums .= "6"
~^7::Nums .= "7"
~^8::Nums .= "8"
~^9::Nums .= "9"
return

~Ctrl Up::
    if (Nums != "") {
        JumpToSlide(Nums)
        Nums := "" ; 초기화
    }
return

JumpToSlide(target) {
    try {
        ppt := ComObjActive("PowerPoint.Application")
		;ppt.ActiveWindow.ViewType=9 	;ppViewNormal
        pres := ppt.ActivePresentation

        ; 문자로 저장된 target을 숫자로 변환
        slideIdx := target + 0
		;msgbox, %slideIdx%

        ; 전체 슬라이드 개수 확인
        maxSlides := pres.Slides.Count

        ; 슬라이드 범위 확인 후 이동
        if (slideIdx >= 1 && slideIdx <= maxSlides) {
            ppt.ActiveWindow.View.GotoSlide(slideIdx)   ;jump to the target slide
        } else {
            ; 범위를 벗어날 경우 알림이 필요하다면 아래 주석을 해제하세요.
            MsgBox,,, % "범위 초과: " . slideIdx . " (전체 " . maxSlides . "장)",5
        }
    } catch {
        ; 파워포인트 비활성
    }
}

#IfWinActive

ExitMenu:
^x::
	ExitApp

첨부한 Jump2Slide.exe를 다운로드 받아 속성에서 차단해제하시고 실행하세요.

Jump2Slide Autohotkey

엑셀 데이터를 다른 창 입력란에 자동으로 일괄 붙여넣기

쵸코난 — Thu, 22 Jan 2026 08:30:41 +0900

엑셀 시트에 데이터를 생성, 정리해놓고

웹브라우저나 DB시스템 등에 자료를 입력해야하는 상황에서

직접 손으로 입력하기에는 너무 힘들기 때문에

VBA를 이용해서 자동화할 수 있습니다.

주로 SendKeys를 이용해서

데이터를 복사하고 붙여넣은 다음 Sleep으로 잠시 대기하고

다음 행의 데이터를 붙여넣는 방식입니다.

#If VBA7 Then
    Declare PtrSafe Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As LongPtr
    Declare PtrSafe Function SetForegroundWindow Lib "user32" (ByVal hwnd As LongPtr) As Long
    Declare PtrSafe Function IsIconic Lib "user32" (ByVal hwnd As LongPtr) As Long
    Declare PtrSafe Function ShowWindow Lib "user32" (ByVal hwnd As LongPtr, ByVal nCmdShow As Long) As Long
    Declare PtrSafe Sub Sleep Lib "kernel32" (ByVal Milliseconds As LongPtr)
    Dim hwnd As LongPtr
#Else
    Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
    Declare Function SetForegroundWindow Lib "user32" (ByVal hwnd As Long) As Long
    Declare Function IsIconic Lib "user32" (ByVal hwnd As Long) As Long
    Declare Function ShowWindow Lib "user32" (ByVal hwnd As Long, ByVal nCmdShow As Long) As Long
    Declare Sub Sleep Lib "kernel32" (ByVal Milliseconds As Long)
    Dim hwnd As Long
#End If

Const SW_RESTORE = 9

'   ********
'   주의사항!!
'
'   반드시 붙여넣을 대상 윈도우창에서 '첫번째 입력칸'을 선택한 상태에서 
'   엑셀창에는 붙여넣을 내용이 입력된 첫번째 셀을 선택하고 실행할 것!
'
'   ********

Sub A1_PasteOver()

    Dim sht As Worksheet
    Dim r As Range
    Dim str$, usr$, sTitle$, targetCol$, i%, firstrow&, lastrow&, TabCount%
    
    '크롬창 찾기
    'sTitle = "제목 없는 설문지 - Chrome"
    'hwnd = FindWindow(vbNullString, sTitle) '윈도우 창이름으로 찾기
    'sTitle = "Chrome_WidgetWin_1"
    'hWnd = FindWindow(sTitle, vbNullString)   '클래스 이름으로 찾기
    hwnd = GetPreviousVisibleWindow(2)
    If hwnd = 0 Then MsgBox "대상 윈도우창 찾기 실패", vbCritical: Exit Sub
    
    firstrow = ActiveCell.Row
    Set sht = ActiveSheet
    targetCol = Split(ActiveCell.Address(True, True), "$")(1) '대상 컬럼 기호  (Ex: F열)
    lastrow = sht.Cells(sht.Rows.Count, targetCol).End(xlUp).Row
    
    '확인
    sTitle = GetWindowTitle$(hwnd)
    usr = InputBox("대상 윈도우 창: [" & sTitle & "] 창" & vbNewLine & _
            "(첫번째 입력란이 선택되어 있어야 함)" & vbNewLine & vbNewLine & _
            "소스 데이터: 현재 시트의 " & targetCol & firstrow & "부터 " & targetCol & lastrow & "까지" & vbNewLine & vbNewLine & _
            "각 데이터를 입력한 후 <TAB>키 입력횟수는?" & vbNewLine & "(데이터 사이의 입력필드 개수에 따라 다름)?", _
            "엑셀 데이터 연속 붙여넣기 자동화", 1)
    usr = Trim(usr)
    If Len(usr) = 0 Or Not IsNumeric(usr) Then Exit Sub
    TabCount = CInt(usr)
    
    '대상 윈도우창 활성화
    If IsIconic(hwnd) Then ShowWindow hwnd, SW_RESTORE
    SetForegroundWindow hwnd
    'AppActivate sTitle, True
    
    '입력할 셀 순환
    For Each r In sht.Range(targetCol & firstrow & ":" & targetCol & lastrow)
        
        '내용을 클립보드에 복사
        str = Trim(r.Text)
        SetCB str
        Sleep 100
        
        '기존 입력 내용이 사라지도록 먼저 전체선택
        'Application.SendKeys "^a", True
        'Sleep 100
        
        '입력칸에 붙여넣기
        Application.SendKeys "^v", True
        Sleep 100
                
        'TAB키를 x번 눌러 다음 입력칸으로 이동
        'TabCount = 1
        For i = 1 To TabCount
            Application.SendKeys "{TAB}", True
            Sleep 100
        Next i
        
    Next r
    
End Sub

 
'https://blog.naver.com/program114/220401934980
'// 클립보드에 텍스트 쓰기
Public Function SetCB(ByRef sText As String) As Boolean ' ### 리턴값: 성공 여부
    On Error GoTo nErr
    Dim Clipboard As Object
'    Microsoft Forms 2.0 Object Library
    Set Clipboard = CreateObject("new:{1C3B4210-F441-11CE-B9EA-00AA006B1A69}")
    Clipboard.SetText sText
    Clipboard.PutInClipboard
    SetCB = True
nErr:
End Function


'// 클립보드의 텍스트 읽기
Public Function GetCB$()
    On Error GoTo nErr
    Dim Clipboard As Object
'    Microsoft Forms 2.0 Object Library
    Set Clipboard = CreateObject("new:{1C3B4210-F441-11CE-B9EA-00AA006B1A69}")
    Clipboard.GetFromClipboard
    GetCB = Clipboard.GetText
nErr:
End Function

Sub A2_RemoveBlankLines()
    
    Dim rng As Range
    Dim l As Long
    
    Set rng = ActiveWindow.Selection
    For l = rng.Rows.Count To 1 Step -1
        If rng.Cells(l, 1).Text = "" Then
            rng.Cells(l, 1).Delete Shift:=xlUp
        End If
    Next l
    
End Sub

Sub A3_DeleteEmptyCells()

    On Error Resume Next ' 선택 영역에 빈 셀이 없을 경우 발생하는 에러 방지
    Selection.SpecialCells(xlCellTypeBlanks).Delete Shift:=xlUp
    On Error GoTo 0
    
End Sub

사례 1:

먼저 웹브라우저에 아래와 같은 설문양식이 있습니다.

각 질문에 차례로 답변을 입력해야 합니다.

첫번째 입력란을 선택한 상태에서 엑셀창에서 데이터를 준비합니다.

즉, 웹브라우저 창위에 엑셀창이 있어야 합니다.

엑셀 시트에 위에 웹브라우저창에 입력할 내용을 아래와 같이 A1:A10에 정리했습니다.

Alt+F8을 누르고 PasteOver 매크로를 실행합니다.

RemoveBlankLines는 모든 빈 줄을 삭제하고 아래줄을 위로 당깁니다.

DeleteEmptyCells는 모든 빈 셀을 삭제하고 아래 셀을 위로 당깁니다.

그러면 아래와 같은 확인창이 뜹니다.

대상 윈도우창 제목을 확인하세요. 대상 윈도우창이 맞아야 엑셀 데이터가 해당 창에 붙여넣어집니다.

※ 주의) 반드시 첫번째 입력란이 선택되어 있고 엑셀창 이전 윈도우창이어야 합니다.

소스 데이터는 엑셀 시트에 현재 선택된 행부터 맨 아래행까지입니다.

※ 주의) 엑셀 시트에서 데이터 시작 셀을 선택해야 합니다.

그리고 입력 데이터 사이사이마다 <TAB>키를 몇번 입력할 지 숫자를 입력합니다.

이 경우는 한 문장 입력하고 탭키를 한 번만 치면 다음 입력란으로 이동하기 때문에 1을 입력합니다.

확인을 누르면 아래와 같이 자동으로 10문장을 답란 칸에 차례로 붙여넣습니다.

대상 창의 입력 환경에 따라 입력할 때 수정할 부분은 아래 부분을 고치면 되겠습니다.

예를 들어 기존 데이터를 지우고 붙여넣는다면 ^a 즉 Ctrl+a를 누르고 모두 선택한 상태에서 붙여넣게 합니다.

SendKeys에서 Ctrl은 ^, Alt 는 %, Shift는 + 기호를 사용합니다. SendKeys "+a" 는 Shift+a 를 입력해줍니다.

또는 지연 시간을 Sleep 100 을 수정합니다. 1000이 1초에 해당합니다.

'입력할 셀 순환
    For Each r In sht.Range(targetCol & firstrow & ":" & targetCol & lastrow)
        
        '내용을 클립보드에 복사
        str = Trim(r.Text)
        SetCB str
        Sleep 100
        
        '기존 입력 내용이 사라지도록 먼저 전체선택
        'Application.SendKeys "^a", True
        'Sleep 100
        
        '입력칸에 붙여넣기
        Application.SendKeys "^v", True
        Sleep 100
                
        'TAB키를 x번 눌러 다음 입력칸으로 이동
        'TabCount = 1
        For i = 1 To TabCount
            Application.SendKeys "{TAB}", True
            Sleep 100
        Next i
        
    Next r

SendKeys 에서 활용 가능한 특수키는 아래 링크를 참조하세요.

https://learn.microsoft.com/en-us/office/vba/language/reference/user-interface-help/sendkeys-statement

그리고 참고로 아래는 이전 윈도우창을 찾을 때 사용하는 코드입니다:

현재 엑셀 창 바로 아래에 웹브라우저 등의 윈도우 창이 붙여넣을 대상 윈도우창인데 이 창을 찾기 위한 작업입니다.

EnumWindows로 윈도우창 목록을 배열로 만들고

바로 이전 윈도우의 hWnd 값을 찾아내고

getWindowText로 윈도우 창 타이틀을 가져옵니다.

Option Explicit

#If VBA7 Then
    Declare PtrSafe Function EnumWindows Lib "user32" _
        (ByVal lpEnumFunc As LongPtr, ByVal lParam As LongPtr) As Long
    Declare PtrSafe Function IsWindowVisible Lib "user32" _
        (ByVal hwnd As LongPtr) As Long
    Declare PtrSafe Function GetWindowText Lib "user32" Alias "GetWindowTextA" _
        (ByVal hwnd As LongPtr, ByVal lpString As String, ByVal cch As Long) As Long
#Else
    Declare Function EnumWindows Lib "user32" _
        (ByVal lpEnumFunc As Long, ByVal lParam As Long) As Long
    Declare Function IsWindowVisible Lib "user32" _
        (ByVal hwnd As Long) As Long
    Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" _
        (ByVal hwnd As Long, ByVal lpString As String, ByVal cch As Long) As Long
#End If

#If VBA7 Then
    Public gHWNDs() As LongPtr
#Else
    Public gHWNDs() As Long
#End If

Dim gCount As Long

#If VBA7 Then
Public Function EnumWindowsProc(ByVal hwnd As LongPtr, ByVal lParam As LongPtr) As Long
#Else
Public Function EnumWindowsProc(ByVal hwnd As Long, ByVal lParam As Long) As Long
#End If

    ' 보이는 창만 수집
    If IsWindowVisible(hwnd) <> 0 And Len(GetWindowTitle(hwnd)) > 0 And hwnd <> Application.hwnd Then
        gCount = gCount + 1
        ReDim Preserve gHWNDs(1 To gCount)
        gHWNDs(gCount) = hwnd
    End If

    EnumWindowsProc = 1 ' 계속 열거
End Function

#If VBA7 Then
Public Function GetPreviousVisibleWindow(ByVal n As Long) As LongPtr
#Else
Public Function GetPreviousVisibleWindow(ByVal n As Long) As Long
#End If

    gCount = 0
    Erase gHWNDs

    ' 모든 창 열거
    EnumWindows AddressOf EnumWindowsProc, 0

    ' n번째 창 반환
    If gCount >= n Then
        GetPreviousVisibleWindow = gHWNDs(n)
    Else
        GetPreviousVisibleWindow = 0 ' n번째 창 없음
    End If
End Function

#If VBA7 Then
Public Function GetWindowTitle(tHwnd As LongPtr) As String
#Else
Public Function GetWindowTitle(tHwnd As Long) As String
#End If
    Dim title As String * 256
    Dim lenTitle As Long
    
    If tHwnd = 0 Then
        GetWindowTitle = ""
        Exit Function
    End If

    lenTitle = GetWindowText(tHwnd, title, 256)
    GetWindowTitle = Left$(title, lenTitle)
    GetWindowTitle = Replace(GetWindowTitle, Chr(0), "") 'NULL문자 제거
End Function

Private Sub getPreviousVisibleWindow_Test()
#If VBA7 Then
    Dim hwnd2 As LongPtr
#Else
    Dim hwnd2 As Long
#End If
    Dim title2 As String

    'Module2.ListAllWindows
    
    ' 2번째 보이는 창
    hwnd2 = GetPreviousVisibleWindow(2)
    title2 = GetWindowTitle(hwnd2)

    If hwnd2 <> 0 Then

        Debug.Print "======= 2번째 보이는 창 hwnd = "; hwnd2
        Debug.Print "타이틀 = "; title2
    Else
        Debug.Print "2번째 보이는 창 없음"
    End If
End Sub

VBA가 포함된 샘플 파일 첨부합니다.

PasteOver1.xlsm

0.03MB

사례2:

아래한글 문서에 아래와 같은 표 양식이 있습니다. 성명란에 이름을 쭉 입력하려고 합니다.

방문자 명단.hwp

0.03MB

아래한글 도구 메뉴 > 환경설정에서 표 안에서 <TAB>키로 다음 셀로 이동할 수 있게 설정되어 있어야 합니다.

한글창 바로 위에 엑셀창이 있고

엑셀시트에는 아래처럼 이름이 정리되어 있습니다.

Alt+F8을 누르고 PasteOver 매크로를 실행합니다.

이 경우는 <Tab>키를 4번 치면 다음 이름칸에 도착하므로 4를 입력합니다.

확인을 누른 결과입니다.

다음 국적 데이터를 선택하고 한 번 더 실행하면 되겠습니다.

아니면 코드를 약간 더 수정해서 여러열을 붙여넣게 할 수 있습니다.

물론 아래한글의 경우 한글 HWP 컨트롤을 이용해서 더 정확하게 자동화할 수 있지만

간단히 SendKeys로 이렇게 일괄 입력 작업을 처리할 수 있습니다.

✅ 활용 예시:

- 엑셀 데이터를 웹브라우저 설문조사 입력란에 일괄로 붙여넣기

- 학원/학교에서 학생 평가자료나 평가문을 출력 양식 프로그램에 일괄로 입력하기

- 아래한글 메일머지 대신 봉투 주소/수신자 등 일괄 입력

- 대규모 DB작업

- 실험 데이터 일괄 입력

- 기타 일괄 입력이 어려운 프로그램창에 엑셀데이터 일괄 입력

향후 개선 사항:

- 키보드 매크로에 가까운 방법이라 한계가 있음

- 데이터가 정확히 해당란에 입력되는지 확인 필요. 중간에 누락된 명단이 있다면 입력 오류 발생.

- 웹의 경우 Json 이나 POST 데이터로 서버에 보내는 방식이 더 정교한 입력방식임

- 시스템의 상황에 따라 키보드로 붙여넣을 때 엉뚱한 창에 데이터가 붙여넣어질 수 있음

✔️❌주의사항:

- 위 내용은 데이터 일괄 입력방법에 대한 순수한 교육적 목적의 자료임

- 불법적인 목적으로 오남용하지 않아야 함.

- 책임은 사용자에게 있음

- 개인적인 용도와 작업에만 사용해야 함

엑셀로 영상 편집하기?

쵸코난 — Mon, 15 Dec 2025 00:39:04 +0900

엑셀로 영상을 편집한다?

숫자를 계산하는 용도인 엑셀로 동영상을 편집한다니

말도 안되는 이야기처럼 보이지만

아래처럼 영상의 시간을 입력해서 영상을 규칙적으로 자르고 일정 부분을 추출해서 최종 영상으로 합칠 수 있습니다.

특히 고프로나 DJI Action, AcePro , Insta360 등 액션카메라나 휴대폰으로 촬영한 몇시간짜리 긴 영상이 있을 때

프리미어나 다빈치 리졸브, 파이널컷, 캡컷, 샷컷 등의 영상 편집프로그램을 이용하지 않고

전체 영상을 2분마다 3초씩 추출해서 하나의 랜덤 기록 영상을 만들고 싶을 때 이용하면 효과적입니다.

물론 엑셀에서 영상을 직접 편집하는 것은 아니고

FFMPEG 이라는 커맨드라인 프로그램에 명령을 보내서 처리합니다.

https://www.ffmpeg.org/download.html

엑셀 VBA는 중간에서 FFMPEG에 보낼 명령어를 생성해서

순차적으로 보내주는 역할을 수행합니다.

활용 순서:

1. RandCut1.xlsm 을 다운로드 받아 파일 속성에서 차단해제하고 나서 열 때 매크로를 허용합니다.

(아래 버전은 버전1이고 맨 아래에 최신 버전을 다운로드하세요.)

RandCut1.xlsm

0.09MB

2. 동영상 파일을 한 폴더에 모두 집어 넣습니다. 파일명이 시간 순서로 정렬되어 있어야 합니다.

3. 고프로 영상의 경우 파일순서가 섞일 수 있으므로 Rename 탭에서 파일 이름을 변경합니다.

Get Folder 버튼을 누르고 폴더 안에 들어가서 확인을 누르면

폴더내의 영상에 대한 미디어정보와 변경될 파일명이 뜨는데 이 때 Rename Files버튼을 눌러 파일명을 시간순서대로 정렬합니다.

4. Config탭에서 환경을 설정합니다.

FFMPEG.EXE의 위치를 C:\FFMPEG\ffmpeg.exe 과 같이 입력합니다.

각 영상 미리보기용 프로그램의 위치를 C:\DaumPot\PotPlayer17\PotPlayerMini64.exe 과 같이 입력합니다.

A열의 시간들은 각 영상을 1차적으로 나눌 시간 길이목록입니다.

B열의 시간들은 1차적으로 나눈 영상에서 최초 가져올 시간길이 목록입니다.

이 시간 목록들이 나중에 기본으로 뜨게 되는 시간들입니다. 처음에는 안건드려도 됩니다.

5. RandCut 탭을 선택합니다. GetFolder 를 누르고 영상이 들어 있는 폴더 안으로 들어가서 '확인'을 누릅니다.

파일명과 간단한 미디어정보를 불러옵니다.

6. 타이틀 제목 영상 삽입 여부를 선택합니다.

타이틀 영상은 해당 폴더명을 검은 배경위에 띄운 단순한 짧은 타이틀 영상입니다. (FFMPEG을 이용합니다.)

7. 영상 썸네일을 생성 여부를 선택합니다. 영상이 많으면 작업시간이 좀 걸립니다.

8. F2와 G2셀에 전체적인 1차 분할시간과 2차 추출시간을 설정합니다.

1차 분할시간 마다 영상을 나눈 다음 초반의 2차 추출시간만큼 영상을 추출하는 규칙입니다.

만약 00:02:00 과 0:00:02 라면 2분마다 초반 2초를 추출합니다.

이 설정은 글로벌 설정으로 각 영상에 특수한 분할시간이 지정되지 않은 한 항상 규칙대로 영상을 추출합니다.

9. 각 영상의 썸네일을 클릭해서 영상 내용을 확인하고 각 영상에 특별한 시간 설정이 필요한 경우 오른쪽에 개별 시간을 설정합니다.

예를 들어 7행의 영상은 매 30초마다 초반 5초의 영상을 추출합니다.

타이틀 영상은 기본 2차 추출 시간만큼의 길이로 자동 생성됩니다.

여러셀을 선택한 상태에서 시간을 한 번 설정하면 선택된 모든 영상이 적용됩니다.

10. (선택 옵션) 만일 Alt+F8 누르고 SetMinimalDuration을 실행하면

아래 지정한 길이의 시간 이내의 영상들은 모두 각 영상의 최대 길이로 설정해줍니다.

즉 6초 이내의 영상은 모두 영상 길이만큼 재생하도록 해줍니다.

11. Start Processing 을 누르면 작업을 시작합니다.

현재 작업중인 영상을 선택하면서 작업 진행상황을 보여줍니다.

12. 최종 영상은 언더바(_) + 폴더명.mp4 로 영상들이 있는 폴더내에 생성됩니다.

아래와 같이 합치는 과정에 뜨는 메시지가 cmd창에 뜹니다. 노란색 경고내용은 영상 시작 위치가 연속적이지 않을 때 뜨는 내용입니다. ( 안뜨게 하려면 아래 명령어 수정부분 참조)

아무 키나 누르면 아래처럼 최종 mp4 파일의 위치를 안내하고

임시파일과 폴더를 삭제할지 묻습니다.

분할된 파일이나 추출된 부분 영상이 필요한 경우가 아니라면 삭제하는 것이 좋습니다.

13. 최종 영상을 확인합니다.

샘플 추출 영상 (2분마다 2초 추출) - 키프레임 위치가 아니라서 정확히 10분마다 잘려지지는 않았습니다.

참고: 영상을 2분씩 잘라서 초반 3초 영상을 추출하는 배치 명령어

rem ## for increasing numbers in 4 digit
set sum=1000
setlocal enabledelayedexpansion

rem ## loop each chunk
for %%A in (*.mp4) do (

set /a sum+=1 

rem ## [1000]o000.mp4, [1000]o001.mp4....[1001]o000.mp4, [1001]o001.mp4 ...
ffmpeg -i %%A -movflags use_metadata_tags -c copy -segment_time 00:02:00 -f segment -reset_timestamps 1 -y [!sum!]%%03d.mp4

rem ## loop each child chunk
for %%F in ([!sum!]*.mp4) do (

rem ## _1000_[1000]o000.mp4, _1000_[1000]o001.mp4,....1001_[1001]o000.mp4, 1001_[1001]o001.mp4...
ffmpeg -i %%~F -movflags use_metadata_tags -c copy -to 00:00:03 -y out_%%~nF.mp4 

rem ## delete parent chunk
del %%~F
)

)
rem #done

VBA코드상의 썸네일 추출 명령 부분 발췌

        cmd = Chr(34) & FFMPEG_PATH & Chr(34) & " -ss 00:00:01 -i " & Chr(34) & mPath & mFile & Chr(34) & _
            " -y -vf " & Chr(34) & "thumbnail,scale=320:-1" & Chr(34) & " -update 1 -frames:v 1 " & Chr(34) & tFile & Chr(34)

타이틀 제목 영상을 생성하는 부분 발췌

Command = Chr(34) & FFMPEG_PATH & Chr(34) & " -y -i " & Chr(34) & InputFilePath & Chr(34) & _
                " -vf drawbox=color=black:t=fill -af volume=0 -to " & CLIP_DURATION & " " & _
                Chr(34) & OutputFilePath & Chr(34)
                
Command = Chr(34) & FFMPEG_PATH & Chr(34) & " -hide_banner -y -i " & Chr(34) & InputFilePath & Chr(34) & _
                " -vf " & Chr(34) & "[in]drawtext=text='" & BASE_DIR_TITLE & "':" & _
                "fontfile='C\:\\Users\\user\\AppData\\Local\\Microsoft\\Windows\\Fonts\\Paperlogy-5Medium.ttf':" & _
                "fontcolor=white:fontsize=78:x=(w-text_w)/2:y=(h-text_h)/2" _
                & ", drawtext=text='" & Replace(Mid([F2].text, 3), ":", "\\\:") & " " & Replace(Mid([G2].text, 3), ":", "\\\:") & _
                "':fontcolor=gray@0.3:fontsize=28:x=w-tw-10:y=h-th-10[out]" _
                & Chr(34) & " " & Chr(34) & OutputFilePath & Chr(34)

1차 분할하는 부분 발췌

            ' FFmpeg 1차 분할
            ' 출력: BASE_DIR/_Temp_Chunks/[ROW번호]_chunk_001.mp4, 002.mp4...
            Command = Chr(34) & FFMPEG_PATH & Chr(34) & " -y -i " & Chr(34) & InputFilePath & Chr(34) & _
                      " -c copy -segment_time " & SEGMENT_TIME & " -f segment -reset_timestamps 1 -y " & _
                      Chr(34) & ChunkPath & Format(RowIndex - 4, "000") & "_" & InputFileNameWithoutExt & "_chunk_%03d.mp4" & Chr(34)

2차 추출하는 부분 발췌

        ' FFmpeg 2차 추출
        ' 출력: BASE_DIR/_Temp_Final/[청크파일명].mp4            ' -correct_ts_overflow 0
        Command = Chr(34) & FFMPEG_PATH & Chr(34) & _
            " -ss " & StartingTime & _
            " -y -i " & Chr(34) & ChunkFilePath & Chr(34) & _
            " -to " & CLIP_DURATION & _
            " -c copy " & _
            " " & _
            Chr(34) & FinalClipPath & ClipFileNameWithoutExt & ".mp4" & Chr(34)

- 여기서 미리 StartingTime = "00:00:00.100"을 주기 때문에 최종 결과에서 노란색 경고가 뜹니다.

StartingTime ="" 로 없애면 뜨지 않습니다.

StartingTime을 0.1초 지정하면 연속된 영상의 소리가 튀지 않고 연속되는 장점이 있습니다.

대신 간혹 영상이 약간 버퍼링이 생기는 점은 단점입니다.

- 영상이 길고 파일이 많을수록 작업시간이 길어집니다.

- 이상으로 엑셀 자동 랜덤 영상 추출기 소개를 마칩니다.

긴 영상을 랜덤으로 몇 초씩 추출해서 빠르게 랜덤 영상을 만들 때 이용해보세요.

참고) 삽입된 상징 이미지들은 Google Gemini 에서 생성하였습니다.

2026.01.19 추가

RandCut11.xlsm

0.08MB

- 서브 타이틀 삽입 가능 : 메인 타이틀 외에도 중간에 특정 영상 앞에 검은 배경에 부제목 영상을 삽입합니다.

- 우클릭 메뉴를 추가 : 마우스 우클릭 > RandCut 메뉴 추가

중간 부제목 추가 결과 해당 동영상 바로 위에 '중간 부제목' 영상이 추가됩니다. 파일명 뒤에 " Title" 이 붙습니다.

엑셀 독립된 새로운 인스턴스로 추가 실행

쵸코난 — Sat, 8 Nov 2025 21:19:08 +0900

엑셀은 새 문서가 열릴 때 기존 엑셀 인스턴스가 실행중이면

프로그램을 통합해서 하나의 엑셀 인스턴스에서 파일을 처리하도록 합니다.

엑셀 인스턴스는 최대 2GB정도의 메모리를 차지하기 때문에

이렇게 인스턴스를 통합하도록 고안되었다고 합니다. 다른 오피스 프로그램도 마찬가지입니다.

문제는 하나의 프로그램으로 두 개의 파일을 처리하게 된 결과

한 쪽에서 채우기 색상을 바꾸면 다른 창의 인터페이스에도 영향을 미치게 됩니다.

상태표시줄 표시도 선택된 하나의 창에만 나오게 됩니다.

이 문제를 해결하려면 엑셀 프로그램이 하나로 합쳐지지 않게 해야 합니다.

아래처럼 레지스트리를 설정해서 항상 매 파일마다 독립적으로 실행할 수도 있습니다.

https://learn.microsoft.com/en-us/troubleshoot/microsoft-365-apps/excel/force-excel-to-open-new-instance

그런데 위 방법은 메모리 부담이 커지게 됩니다.

그보다는 아래처럼 필요할 때 독립적으로 엑셀 인스턴스를 추가로 시작하도록 하세요.

>> 먼저 엑셀을 실행하고 상태표시줄의 엑셀창 제목 우클릭 > Excel을 Alt+클릭 후 새 엑셀 인스턴스 시작

그러면 서로 영향을 미치지 않아 (서로 다른 프로그램 ID를 가져서)

독립적으로 사용 가능하고 두 가지 문제 모두 해결됩니다. 단, 메모리는 더 많이 사용하게 됩니다.

당연한 이야기이지만 365나 2024버전 엑셀과 구버전 2010, 2013버전을 두 개 따로 실행하는 방법도 가능합니다.

이 방법은 엑셀에서만 작동하고 파워포인트나 워드는 작동하지 않습니다.

참고: 지식인

슬라이드쇼에서 엔터를 치면 무조건 다음 슬라이드로 이동

쵸코난 — Fri, 7 Nov 2025 16:08:05 +0900

파워포인트 슬라이드쇼에서 <엔터>를 치면 애니메이션이 중단되고 다음 애니메이션으로 넘어갑니다. 더이상 애니메이션이 없으면 다음 슬라이드로 넘어갑니다. 이것은 파워포인트 슬라이드쇼의 정상적인 동작입니다.

이 때 슬라이드쇼에서 <엔터>를 치면 애니메이션이션이 있더라도 무조건 다음 슬라이드로 넘어가는 것을 원하는 경우입니다.

1. 단순한 방법은 키보드 대신 특정부분을 마우스를 클릭해서 다른 슬라이드로 가도록 따로 하이퍼링크를 추가하는 것이 간단한 방법입니다.

슬라이드 마스터 레이아웃에 링크를 넣어두고 모든 슬라이드에 적용하면 일괄로 처리 가능합니다.

하이퍼링크가 보이는 것 그리고 마우스 클릭으로 넘어가는 점이 단점입니다.

2. 아니면 외부 프로그램이나 VBA의 도움을 받아야 합니다.

VBA로 하려면 실시간으로 키보드 입력을 감시하는 코드가 필요해서 복잡해지므로

외부 Autohotkey 프로그램을 이용해보겠습니다.

아래와 같은 오토핫키 코드로 단축키 프로그램을 실행해 놓으면

엔터키가 눌리면 바로 다음 슬라이드로 넘어가게 할 수 있습니다.

주요부분:

#IfWinActive, ahk_class screenClass ;frameClass
$ENTER::
	try {
		App := ComObjActive("PowerPoint.Application")
		Prs := App.ActivePresentation
		pos := Prs.SlideShowWindow.View.CurrentShowPosition + 1
		if ( pos <= Prs.Slides.Count ) {
			App.SlideShowWindows(1).View.GotoSlide(pos, -1) 
		;Sleep, 100
		}
	}
	catch e {
		;no ppt
		if (!app) {
			MSgBox, PPT application not found.
		}
		else {
			MsgBox, % e.Message
		}	
	}
 
return

첨부파일 EXE를 실행하면 아래 창이 뜹니다. 확인을 누르면 상태표시줄로 최소화됩니다.

이제 슬라이드쇼에서 엔터를 치면 애니메이션이 진행중이어도 바로 다음 슬라이드로 진행합니다.

스페이스나 방향키는 기존대로 다음 애니메이션단계로 넘어갑니다.

아래 예시에서 1슬라이드에서 스페이스키를 누르면 다음 애니메이션 단계로 가서 멈추지만

2슬라이드에서 엔터를 누르면 바로 다음 3슬라이드로 넘어갑니다.

10,11,12 슬라이드도 애니메이션이 올라오지만 엔터키를 눌러서 바로 다음 슬라이드로 넘어갑니다.

현재 일반 파워포인트 슬라이드쇼와 발표자 보기에서 작동합니다.

(창 클래스 이름이 달라서 웹형식 보기에서는 지원하지 않습니다.)

첨부파일 참고하세요.

관련: 지식인

좀 더 범용으로 사용할 수 있게 변경한 버전입니다.

바로 이전 슬라이드는 PgUp,
바로 다음 슬라이드는 PgDn,
마지막으로 본 슬라이드는 BackSpace 키

(애니메이션 초기화하지 않습니다. 이동 후 멈췄던 애니메이션부터 시작합니다.)

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
#SingleInstance
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
 
	WinSetTitle, Jump2
	
	MsgBox,0x40,Jump2,During a Powerpoint SlideShow`,`nhit <PgUp>/<PgDn> to directly jump to the prev/next slide or `nhit <BackSpace> to go back to the last slide viewed`n`nHit <Win+X> to quit this hotkey,15
	
	if (%A_IsCompiled%)  {
		Menu, Tray, Icon, %A_ScriptName%, 1
	}
	Menu, Tray, NoStandard
	Menu, Tray, Add, Exit, ExitMenu
 
return
 

#IfWinActive, ahk_class screenClass ;frameClass
$PGDN::
	try {
		App := ComObjActive("PowerPoint.Application")
		Prs := App.ActivePresentation
		pos := Prs.SlideShowWindow.View.CurrentShowPosition + 1
		if ( pos <= Prs.Slides.Count ) {
			App.SlideShowWindows(1).View.GotoSlide(pos, 0) ;, -1) 
		}
	}
	catch e {
		;no ppt
		if (!app) {
			MSgBox, PPT application not found.
		}
		else {
			MsgBox, % e.Message
		}	
	}
 
return

$PGUP::
	try {
		App := ComObjActive("PowerPoint.Application")
		Prs := App.ActivePresentation
		pos := Prs.SlideShowWindow.View.CurrentShowPosition - 1
		if ( pos >= 1 ) {
			App.SlideShowWindows(1).View.GotoSlide(pos, 0)	;, -1) 
		}
	}	
	catch e {
		;no ppt
		if (!app) {
			MSgBox, PPT application not found.
		}
		else {
			MsgBox, % e.Message
		}	
	}
 
return

$BACKSPACE::
	try {
		App := ComObjActive("PowerPoint.Application")
		Prs := App.ActivePresentation
		pos := Prs.SlideShowWindow.View.LastSlideViewed.SlideIndex 
		App.SlideShowWindows(1).View.GotoSlide(pos, 0)	;, -1) 
	}	
	catch e {
		;no ppt
		if (!app) {
			MSgBox, PPT application not found.
		}
		else {
			MsgBox, % e.Message
		}	
	}
 
return


#IfWinActive
ExitMenu:
#x::
exitapp

[엑셀+PPT] 초성게임 자동 생성기

쵸코난 — Tue, 28 Oct 2025 10:08:25 +0900

지난번 Word Jumble 게임을 약간만 수정해서 초성게임 생성기를 만들어 보았습니다.

그래픽은 구글 Gemini를 여러번 혹독하게 훈련시키고 수정해서 생성하였습니다.

글자순서를 섞는 대신 한글의 초성만 제시하고 단어나 문구 전체를 맞추게합니다.

특징:

엑셀+PPT조합으로 단어나 한글만 목록으로 작성하면 초성 슬라이드는 알아서 생성해줍니다.
Bomb Game 방식으로 랜덤 문제를 참여자가 선택해서 고르므로 복불복게임이 됩니다.
최종 PPT는 VBA를 사용하지 않아도 힌트기능이나 팀별 점수판까지 작동가능합니다.
엑셀+PPT조합이기 때문에 목록만 만들면 초성퀴즈를 대량으로 생성 가능합니다. 문제 슬라이드 템플릿을 미리 수정해서 다른 디자인이나 애니메이션으로 만들 수도 있습니다.

시연 영상:

샘플파일1:

게임 진행 방식은 Word Jumble 과 같습니다.

현재 샘플은 7 * 6 = 42개의 문제를 출제합니다.

엑셀 파일이 필요합니다.

별다른 양식이 아니라 A2셀부터 아래로 단어 목록을 나열하면 됩니다.

샘플 xlsm 파일에서 Alt+F8 > Random36 매크로를 실행해서 랜덤단어를 추출할 수 있습니다.

단어 개수는 나중에 Bomb Game에서 생성될 버튼 수를 고려하는 것이 좋습니다.

샘플의 매크로는 현재 4글자 단어 7개, 5글자 단어 7개, 6글자 7개, 7글자 7개, 8글자 7개, 9글자 7개로 총 6 * 7= 42개의 단어를 추출합니다. 코드상에서 cs 와 rs 값을 변경하면 원하는 개수대로 추출이 가능합니다.

Bomb 게임에서도 가로 7개, 세로 6행으로 문제로 이어지는 숫자 버튼이 생성될 예정입니다.

(버튼을 생성할 때 대화창이 뜨는데 이 때 버튼 개수를 임의로 변경 가능합니다.)

문제 슬라이드가 자동으로 생성되는데

미리 문제 슬라이드를 수정하고 A_Main 매크로를 실행합니다.

3슬라이드가 문제 슬라이드의 템플릿 즉, 기준 슬라이드입니다.

특히 문제로 제시될 텍스트상자의 폰트나 글자크기, 색상, 애니메이션을 수정할 수 있습니다.

답으로 나타날 텍스트상자도 마찬가지로 미리 수정하면 반영됩니다.

나머지 도형이나 애니메이션도 수정 가능합니다.

이제 매크로를 하나만 실행하면 모든 작업은 일괄로 자동 처리됩니다.

Alt+F8 > A_Main 을 실행합니다.

그리고 나서 단어 목록이 들어 있는 엑셀 파일을 선택합니다.

Questions 구역에 문제 슬라이드가 생성됩니다.

그 다음 Bomb Game 버튼 생성을 위해 버튼 가로 세로 개수를 묻습니다.

기본 숫자 그대로 확인 누르면 됩니다. 원할 경우 여기서 원하는 숫자로 변경합니다.

기본값으로 가로:세로가 비슷하도록 개수를 추천합니다.

아래처럼 7 * 6 개의 숫자 버튼이 생성됩니다.

1행의 7개는 가장 쉬운 4글자 단어로 링크되고, 2행의 7개는 다음 5글자 단어로 링크,....6행의 7개는 가장 어려운 9글자 단어로 링크됩니다.

랜덤으로 적용된 색상이 맘에 들지 않으면 D_ButtonColor 매크로를 여러번 실행할 수 있습니다.

몇개마다 색상을 변경할지 묻습니다. 열 개수를 입력하면 2열마다 색상이 달라지게 합니다.

1개를 입력하면 계속 색상이 번갈아 가면서 반복되겠습니다.

14를 입력하면 두 줄마다 색상이 달라집니다. 총 개수보다 크게 입력하면 모두 같은 색상으로 만듭니다.

1을 입력한 경우 색상이 번갈아 반복됩니다.

참고로 매크로 코드 창에서 Select SimilarColor 매크로를 실행해서 현재 선택한 도형과 같은 색상 도형을 모두 선택해서 색상을 바꿀 수도 있습니다. Select SimilarName 매크로를 이용하면 모든 버튼 도형만 한 번에 선택이 가능합니다.

이제 작업이 완료되었으므로 슬라이드쇼로 확인해봅니다.

8*6=48개짜리로 하나 더 샘플을 만들었습니다. 자동화매크로이므로 대량 생성이 가능합니다.

샘플 파일2:

CommonWords_Kor1.xlsm

0.03MB

초성퀴즈2.pptm

3.39MB

점수 슬라이드 추가 버전

문제슬라이드에서 오른쪽 아래에 Time's up 그림을 누르면 맨 마지막 점수 슬라이드로 이동합니다.

돌아가기 버튼을 누르면 이전 버전 처럼 숫자버튼 선택 슬라이드로 돌아갑니다.

F_TeamSocre라는 코드가 추가되었습니다.

기존에 만들었던 애니메이션 점수판 ( https://konahn.tistory.com/entry/ScoreBoardAnimation ) 을 이용했습니다.

트리거 애니메이션을 이용해서 매크로가 필요 없는 것이 특징입니다.

점수판을 만들 때 팀의 개수와 최고 점수를 입력합니다.

5,10으로 입력하면 5개조로 최대 10점까지 생성됩니다.

너무 높은 점수는 트리거 애니메이션이 버벅이게 되니 주의하세요.

추후에 다시 F_TeamScore를 실행해서 팀개수나 최대 점수를 수정해서 다시 만들 수도 있습니다.

(주의: 슬라이드 마스터의 3번째 레이아웃에서 정답/오답 소리파일과 되돌아가기 아이콘을 복사해옵니다.)

점수판 슬라이드에서 각 조 이름을 클릭하면 점수가 +1 추가되고 추가된 맨 위 점수 도형을 클릭하면 다시 -1 감점할 수 있습니다. 숫자버튼 메인 슬라이드에서 오른쪽 상단에 추가된 점수판 아이콘을 눌러도 점수판 슬라이드로 이동할 수 있습니다. 점수판 슬라이드는 마지막에 5번째 구역을 추가해서 맨 마지막 슬라이드로 추가됩니다. Module3의 ChangeColor 매크로로 팀별 색깔을 랜덤으로 변경하거나 직접 수정이 가능합니다.

실행화면:

샘플파일3(점수 슬라이드 추가 버전):

초성퀴즈3.pptm

3.63MB

기타:

이 프레젠테이션에는 사용된 한글 폰트는 렉시굴림 폰트입니다.
https://offree.net/2234
렉시굴림 도도 수정본
https://blog.naver.com/slayers_dodo/220767325724

Bomb Game 만들 때 필요한 유용한 매크로는 Private 선언을 해서 Alt+F8눌렀을 때 뜨지 않습니다. 직접 코드상에서 녹색 플레이 버튼을 눌러서 실행해야 합니다. 유용한 매크로가 많이 들어 있습니다.
Module2의 유용한 매크로 목록:

Bomb Game 형식이지만 문제 슬라이드에서 모든 애니메이션이 끝났을 때 클릭하면 다음 문제로 넘어갑니다. 뒤로 돌아와서 Round 버튼을 눌러야 번호 선택슬라이드로 돌아옵니다. 화면전환에 체크를 해제하면 되지만 그렇게 되면 클릭할 때 애니메이션이 넘어가지 않고 키보드를 이용해야 해서 그대로 두었습니다.
문제 슬라이드 아래에 자모양 도형의 색상은 그라디언트 색상이 2개일 때만 두번째 색상을 랜덤으로 변경합니다
그래픽은 구글 Gemini를 여러번 채근해서 수정해고 생성/변환하였습니다.

추후 아이디어

여러개의 구역으로 퀴즈 세트를 추가하여 처음 시작할 때 그룹이나 단계를 선택하게 하는 것도 좋겠습니다.

숫자번호 선택 슬라이드에 각 팀별 점수판을 추가할 수도 있겠습니다.

리본메뉴를 눌러서 여러 기능을 수행하게 할 계획도 있습니다.

샘플파일4:

1. 엑셀 파일 B열에 힌트나 카테고리명을 넣어서 Bomb Button에 힌트(카테고리)를 표시할 수 있습니다.

SaveHint2SlideTags()는 엑셀 파일의 힌트를 각 문제 슬라이드의 태그로 저장합니다.

각 문제 슬라이드에 No => 문제 번호, Answer => 정답, Bigo => 힌트(카테고리 혹은 비고) 태그를 저장합니다.

AddHint2BombButtons()는 각 슬라이드 태그의 힌트를 Default 앞 슬라이드의 각각의 Bomb Button 에 표시합니다.

2. TimesUp버튼을 누르면 마지막 슬라이드에서 팀별 점수를 표시할 수 있습니다.

아래버전이 가장 최신 파일입니다.

초성퀴즈31_TE.pptm

2.79MB

Word Jumble + Bomb Game 영어/한글 단어 맞추기 게임 자동 생성기 v2

쵸코난 — Sun, 26 Oct 2025 00:50:54 +0900

이번에는 지난번 Word Jumble 게임을 Bomb Game 형식으로 생성하는 버전도 만들어 보았습니다.

문제 푸는 문제슬라이드는 기존과 동일하고

Bomb Game 형식으로 문제를 골라서 풀고 돌아오는 방식입니다.

게임 실행화면

기존 버전은 차례대로 다음 문제를 푸는 방식이었는데

Bomb Game 은 문제 푸는 사람이 문제를 선택해서 푸는 방식입니다.

문제를 고르는데 더 시간이 소요되고

문제의 난도를 본인이 골랐기 때문에 좀 더 공평성이 가미됩니다.

Bomb Game 제작은 좀 더 손이 많이 가는 작업입니다.

특히 숫자 도형들을 생성하고 트리거 애니메이션을 적용하고

각 문제 슬라이드에 하이퍼링크를 거는 작업은 매우 귀찮은 과정입니다.

이전부터 Bomb Game 제작 자동화를 위해 노력해왔기 때문에

그런 자동화 매크로를 이번 게임 제작이 적극 도입해서 최대한 자동화 처리해보았습니다.

활용방법

기존 매크로와 크게 다르지는 않습니다.

1. 엑셀 파일 준비

지난번과 마찬가지로 단어목록 엑셀파일을 준비합니다.

기본 2행부터 데이터를 인식합니다.

FirstRow=2 여서 그렇습니다.

FirstRow=1로 바꾸면 1행부터 단어를 가져옵니다.

여러 단어에서 랜덤으로 단어를 추출하고 싶다면

아래에 있는 CommomWords_Eng.xlsm 영어단어 랜덤추출기나 CommomWords_Kor.xlsxm 한글단어 랜덤추출기를 이용해도 됩니다.

✅ Word Jumble 샘플파일 다운로드:

WordJumble2.pptm

2.77MB

2. 문제 템플릿 슬라이드 수정

이번에는 3번 슬라이드가 문제 템플릿 슬라이드입니다.

Scrambed 와 Unscrambled 텍스트 상자가 문제와 정답 텍스트상자입니다.

폰트, 글자크기, 글자색상, 텍스트 효과, 애니메이션 효과, 슬라이드 배경 등을 미리 수정합니다.

그대로 두면 기본 설정대로 생성됩니다.

애니메이션 창을 켜고 애니메이션 효과도 수정 가능합니다.

전구모양 힌트 도형은 제목에 있는 전구 아이콘을 복사해서 자동으로 생성합니다.

(제목의 전구모양 아이콘을 삭제하면 오류가 발생하니 지우지 마세요.)

전구그림을 누르면 해당위치의 글자가 힌트로 뜹니다.

(원래는 다시 힌트글자를 지우면 사라지지만 정답 텍스트상자에 가려 반응하지 않습니다.

힌트도형이 맨 위에 생성되게 하면 작동하지만 이 기능은 별로 쓰이지 않을 것 같아 그대로 두었습니다.)

3. 매크로 실행

Alt+F8누르면 아래와 같은 매크로를 실행할 수 있습니다.

A_Main 을 실행하면 일괄처리합니다.

엑셀단어목록파일을 선택해서 단어를 불러와서 템플릿 슬라이드로부터 문제 슬라이드를 일괄 생성한다음

Bomb Game 버튼을 생성하고 트리거 애니메이션과 하이퍼링크를 연결해줍니다.

B_LoadXL은 엑셀파일을 선택해서 문제 슬라이드를 생성합니다.

C_BombChoice는 Bomb Game 버튼 생성, 트리거애니메이션 적용, 하이퍼링크 작업을 합니다.

A_Main 을 실행하면 위 두 가지 처리를 한꺼번에 처리합니다.

C_BombChoice 단계에서 가로, 세로 버튼 개수를 변경 가능합니다. 기본적으로 추천하는 개수대로 하면 됩니다.

실행 결과 2슬라이드에 Bomb Game 버튼이 생성됩니다.

버튼 색깔이 자동으로 교차로 적용됩니다.

마음에 들지 않을 경우에는 일단 D_ButtonColor를 여러번 실행해보세요.

계속 랜덤 색상으로 변경해줍니다.

자신만의 색상으로 변경하고 싶다면

버튼을 하나 선택하고 Module2의 SelectSimilarColor 를 실행해서 같은 색깔 버튼들을 일괄 선택하고

도형 속성에서 그라디언트 색상을 조절해주면 좋습니다.

그 다음 다른 색깔 버튼을 선택하고 한번 더 매크로를 실행해서 색상을 변경하세요.

슬라이드쇼에서 오른쪽 상단 '문제 섞기' 아이콘을 누르면 문제 슬라이드의 순서를 랜덤으로 섞어줍니다.

하이퍼링크도 모두 자동으로 변경됩니다. 엑셀의 단어 목록이 난도가 단계적으로 나뉜 경우 이 버튼을 눌러 랜덤으로 섞어줄 수 있습니다.

4. 작동화면

1. 자주 쓰는 영어단어

자주 쓰는 영어단어 추출용 엑셀 파일

위와 같은 단어 목록에서 Random36을 실행하면 Sheet1에 6*6개의 단어를 랜덤 추출해줍니다.

엑셀 매크로 파일:

CommonWords_Eng.xlsm

0.04MB

ppt 파일:

WordJumble2_CommonWords_Eng.pptm

2.77MB

2. 한글 단어 찾기 (한글 단어도 가능합니다.)

WordJumble2_CommonWords_Kor1.pptm

2.77MB

WordJumble2_CommonWords_Kor2.pptm

2.97MB

(매크로코드는 이 파일이 현재 최신 버전입니다.)

한글 단어 목록 생성용 엑셀파일

CommonWords_Kor.xlsm

0.03MB

아래와 같은 목록에서 Alt+F8 > Random36을 실행하면 Sheet1에 단어목록을 생성합니다.

매크로 실행 결과 Sheet1 에 아래와 같이 7개씩 랜덤으로 추출합니다.

코드상에서 아래 부분의 숫자를 수정하고 실행할 수 있습니다.

cs 가 6이면 Bomb Game 에서 세로행수가 6이고

rs 가 7이면 Bomb Game 에서 가로열수가 7인 경우입니다.

6*7 = 총 42개의 버튼이 생성되게 됩니다.

    Randomize
    cs = 6  ' 레벨 개수. 1레벨 5글자단어, 2레벨 6글자단어,.., 6레벨 10글자단어
    rs = 7  ' 레벨별 단어 개수

5.기타

이 프레젠테이션에는 사용된 폰트는 렉시굴림 폰트입니다.
https://offree.net/2234
렉시굴림 도도 수정본
https://blog.naver.com/slayers_dodo/220767325724

Bomb Game 만들 때 필요한 유용한 매크로는 Private 선언을 해서 Alt+F8눌렀을 때 뜨지 않습니다. 직접 코드상에서 녹색 플레이 버튼을 눌러서 실행해야 합니다. 유용한 매크로가 많이 들어 있습니다.
Bomb Game 형식이지만 문제 슬라이드에서 클릭하면 다음 문제로 넘어갑니다. 뒤로 돌아와서 Round 버튼을 눌러야 번호 선택슬라이드로 돌아옵니다. 화면전환에 체크를 해제하면 되지만 그렇게 되면 클릭할 때 애니메이션이 넘어가지 않습니다.
문제 슬라이드 아래에 자모양 도형의 색상은 그라디언트 색상이 2개일 때만 두번째 색상을 랜덤으로 변경합니다
여러개의 구역으로 퀴즈 세트를 추가하여 처음 시작할 때 그룹이나 단계를 선택하게 하는 것도 좋겠습니다.
숫자선택 슬라이드에 각 팀별 점수판을 추가할 수도 있겠습니다.
리본메뉴를 눌러서 여러 기능을 수행하게 할 계획도 있습니다.

6. 수정 버전

아래처럼 B열에 문제에 대한 힌트나 카테고리 등을 적어놓고

아래 매크로를 추가 실행해서 Bomb Button에 미리 해당 힌트를 보여주게 할 수 있습니다.

- SaveHint2SlideTags()는 엑셀 파일의 힌트를 각 문제 슬라이드의 태그로 저장합니다.

각 문제 슬라이드에 No태그 => 문제 번호, Answer 태그 => 정답, Bigo 태그 => 힌트(카테고리 혹은 비고) 태그를 저장합니다.

- AddHint2BombButtons()는 각 슬라이드 태그중 힌트 태그의 내용을 Default 앞 슬라이드 즉 Bomb Button 슬라이드의 각각의 Bomb Button 에 미리 표시합니다.

또한 문제 슬라이드에서 오른쪽 아래 Time's up 버튼을 누르면 맨 마지막 팀별 점수판 슬라이드로 이동합니다. VBA 없이 트리거 애니메이션으로 구현했습니다. 문제 생성시 팀의 개수와 최고 점을 설정할 수 있습니다. 나중에라도 매크로 중 F_TeamScore를 실행하면 됩니다.

현재 가장 최신 버전입니다.

WordJumble3TS_CommonWords_Eng.pptm

3.15MB

>> 다음에는 이 게임을 조금만 수정해서 초성퀴즈 자동생성기로 만들어 보겠습니다.

Word Jumble 영어단어 철자순서 맞추기 게임 자동 생성기 v1

쵸코난 — Sat, 25 Oct 2025 09:26:41 +0900

구글 Gemini의 도움으로 생성한 로고

Word Jumble 게임은

영어단어 'apple'이 'eplpa'나 'lpape' 로 섞여 있을때 원래 단어 'apple'을 맞추는 게임입니다.

출처: Cambridge Dictionary

섞여 있는 철자의 원래 단어를 찾아내는 것이 쉽지만은 않습니다.

첫글자나 중간 글자에 대한 힌트라도 있다면 좀 더 풀기 편해집니다.

온라인에 Jumble 풀이에 도움을 주는 사이트도 있습니다.

https://jumblesolver.me/

https://jumblesolver.us/

https://word.tips/jumble-solver/

Word Jumble 퀴즈를 파워포인트 슬라이드에 만들 경우에

단어 철자를 섞고 문제를 만드는 것이 귀찮기도 하고 자칫 잘못하면 철자를 틀리기 쉽습니다.

그래서 이번 기회에 여러 단어에 대한 Word Jumble 게임 슬라이드를

일괄로 자동으로 생성하는 VBA매크로를 만들어 보았습니다.

첫번째 버전입니다.

WordJumble1.pptm

2.52MB

위처럼 타이틀 슬라이드, 템플릿 슬라이드, 문제 슬라이드들로 구성됩니다.

Alt+F8을 누르고 Load_XL을 실행하면

엑셀파일 단어 목록으로부터

Word Jumble 문제 슬라이드들을 일괄로 자동 생성합니다.

1, 엑셀파일은 다른 양식이 필요 없고 A1셀부터 아래로 단어목록을 입력하고 저장하면 됩니다.

2. 문제슬라이드가 생성되는 템플릿 슬라이드가 2슬라이드입니다.

매크로 실행 전에 이 슬라이드를 먼저 수정하는 것이 좋습니다.

특히 Scrambled와 Unscrambled 텍스트상자(도형)이 중요합니다.

폰트나 글자색상, 글자크기, 글자효과, 애니메이션이 모두 그대로 문제 슬라이드에 반영됩니다.

슬라이드의 배경이나 제목문구, 라운드 숫자, 10초 타이머 애니메이션, 타임오버 애니메이션 등도 수정해도 됩니다.

제목문구나 여러가지 그래픽은 구글 Gemini의 도움을 받았습니다.

기본적인 애니메이션은 아래와 같이 구성되어 있습니다.

전구아이콘은 힌트 글자가 뜨게하는 트리거 도형인데 자동으로 생성되므로 수정할 필요 없습니다.

(제목에 있는 작은 전구도형을 복사하므로 혹시 지워버리면 힌트가 작동하지 못합니다.)

3. 엑셀 파일과 문제 템플릿 슬라이드가 준비되었다면 이제 매크로 실행만 하면 됩니다.

Alt+F8을 누르고 LoadXL 매크로를 실행하고 엑셀파일을 선택합니다.

4. Questions 영역에 문제 슬라이드들이 복제되어 생성됩니다.

5. 실행 화면

전구모양 힌트 아이콘을 누르면 글자가 나타납니다.

(원래 나타난 글자를 다시 누르면 사라지게 하려고 했으나

나중에 나타나는 정답 글자 아래에 있어서 그 기능은 현재 작동하지 않습니다.)

이 프레젠테이션에는 사용된 폰트는 렉시굴림 폰트입니다.

https://offree.net/2234

렉시굴림 도도 수정본

https://blog.naver.com/slayers_dodo/220767325724

VBA코드입니다.

 Option Explicit

Private Sub NameShapes()
    Dim pNum As Integer, usr$, shp As Shape
    
    usr = InputBox("도형이름 시작문구를 입력하세요.", , "_")
    If Len(usr) = 0 Then Exit Sub
    For Each shp In ActiveWindow.Selection.ShapeRange
        pNum = pNum + 1
        shp.Name = usr & Format(pNum, "00")
    Next shp
End Sub

Function shpExist(oSld As Slide, strName As String) As Boolean
    Dim shp As Shape
    For Each shp In oSld.Shapes
        If shp.Name = strName Then shpExist = True: Exit Function
    Next shp
    shpExist = False
End Function

'shuffle
Sub shufflerange(Optional Notused As Boolean)
    Dim Iupper As Integer, Ilower As Integer
    Dim Ifrom As Integer, Ito As Integer, Default As Integer, i As Integer
    Iupper = ActivePresentation.Slides.Count
    Ilower = Default + 1     'slide number to start shuffle
    If Iupper > ActivePresentation.Slides.Count Or Ilower <= Default Then GoTo err
    For i = 1 To 2 * Iupper
        Randomize
        Ifrom = Int((Iupper - Ilower + 1) * Rnd + Ilower)
        Ito = Int((Iupper - Ilower + 1) * Rnd + Ilower)
        ActivePresentation.Slides(Ifrom).MoveTo (Ito)
    Next i
    MsgBox (Iupper - Ilower) & "slides were mixed in order."
Exit Sub
err:
    MsgBox "ERROR) Generate a new slideshow first.", vbCritical
End Sub

'사용법
' =shuffle(A1) : 첫번째 단어부터 섞기
' =shuffle(A11,2) : 세번째 단어부터 섞기
Private Sub testShuffle()
    Debug.Print Shuffle("try to", 0)
End Sub

Function Shuffle(str As String, Optional Except As Integer = 1) As String
    Dim Words() As String, temp As String
    Dim total As Integer, start As Integer, i As Integer, r As Integer
    
    '주어진 문장 조각내기
    Words = Split(Trim(str), " ")
    total = UBound(Words)
    start = LBound(Words)
    If total = 0 Then Shuffle = str: Exit Function

    '단어 배열 섞기 시작
    Randomize           '랜덤 시드 초기화
    
    '만약 처음 몇단어를 제외하고 섞는다면
    If Except Then start = start + Except
    
    For i = start To total
        r = Int(Rnd * (total - start)) + start
        temp = Words(i)     '랜덤 위치의 배열과 서로 교환
        Words(i) = Words(r)
        Words(r) = temp
    Next i
    
    '결과 문장 생성
    Shuffle = ""
    For i = LBound(Words) To total
        Shuffle = Shuffle & Words(i)
        If i <> total Then Shuffle = Shuffle & " "  '"/ "
    Next i
    Shuffle = Shuffle & ""
    
End Function

Private Sub testScramble()
    Debug.Print Scramble("try to")
End Sub

Function Scramble(word As String) As String
    
    Dim temp() As String
    Dim i  As Integer
    
    word = Shuffle(Trim(word), 0)
    temp = Split(word, " ")
    For i = LBound(temp) To UBound(temp)
        temp(i) = ScrambleWord(temp(i))
    Next i
    If UBound(temp) = LBound(temp) Then
        Scramble = temp(LBound(temp))
    Else
        Scramble = Join(temp, " ")
    End If
End Function

Function ScrambleWord(str As String) As String
    Dim Scr() As String, temp As String
    Dim total As Integer, i As Integer, r As Integer
    
    '주어진 단어 조각내기
    str = StrConv(Trim(str), vbUnicode)
    Scr = Split(Left(str, Len(str) - 1), vbNullChar)
    total = UBound(Scr)
 
    '단어 배열 섞기 시작
    Randomize           '랜덤 시드 초기화

    For i = LBound(Scr) To total
        r = Int(Rnd * total)
        temp = Scr(i)     '랜덤 위치의 배열과 서로 교환
        Scr(i) = Scr(r)
        Scr(r) = temp
    Next i
    
    '결과 단어 생성
    ScrambleWord = Join(Scr, "")
    
End Function

Sub LoadXL()

    Dim FD As FileDialog, xlFile$
    Dim xL As Object, xBook As Object, xSht As Object, xRng As Object, xRngLast As Object
    Dim prs As Presentation, sld As Slide, shp As Shape, Default&, i&
    
    Set prs = ActivePresentation
    Default = 2  '기준 슬라이드
    Set FD = Application.FileDialog(msoFileDialogFilePicker)
    With FD
        .Filters.Clear
        .Filters.Add "Word List Excel", "*.xls?,*.csv"
        .InitialFileName = prs.Path & "\"
        If .Show = -1 Then xlFile = .SelectedItems(1)
    End With
    If xlFile = "" Then Exit Sub
    
    '// 기존 슬라이드 삭제
    If prs.Slides.Count > Default Then
        If MsgBox("기존 슬라이드들을 지울까요?", vbOKCancel) = vbOK Then
            For i = prs.Slides.Count To Default + 1 Step -1
                prs.Slides(i).Delete
            Next i
        End If
    End If
    
    Set xL = CreateObject("Excel.Application")
    If xL Is Nothing Then Exit Sub
    
    Set xBook = xL.workbooks.Open(xlFile)
    Set xSht = xBook.Worksheets(1)
    Set xRngLast = xSht.Cells(xSht.Rows.Count, "A").End(-4162)
    
    For Each xRng In xSht.Range("A1:A" & xRngLast.Row)
    
        Set sld = prs.Slides(Default).Duplicate(1)
        sld.MoveTo prs.Slides.Count
        If xRng.Row = 1 Then sld.MoveToSectionStart 3
        sld.SlideShowTransition.Hidden = msoFalse
        sld.Shapes("Scrambled").TextFrame.TextRange = Scramble(xRng.Text)
        sld.Shapes("Unscrambled").TextFrame.TextRange = Trim(xRng.Text)
        addHint sld
        If sld.Shapes("Ruler").Fill.GradientStops.Count = 2 Then _
            sld.Shapes("Ruler").Fill.GradientStops(2).Color.RGB = RGB(Rnd * 125, Rnd * 125, Rnd * 125)
        sld.Shapes("Round").TextFrame.TextRange = Format(xRng.Row, "00") & " / " & xRngLast.Row
    Next xRng
    
    If Not xBook Is Nothing Then xBook.Close
    If Not xL Is Nothing Then Set xL = Nothing
End Sub

Function delShapes(sld As Slide, pref As String)

    Dim i As Long
    For i = sld.Shapes.Count To 1 Step -1
        If sld.Shapes(i).Name Like pref Then sld.Shapes(i).Delete
    Next i
End Function

Private Sub doAddhint()
    Dim sld As Slide
    Set sld = ActivePresentation.Slides(2)
    addHint sld
End Sub

Function addHint(oSld As Slide)
    
    Dim hshp As Shape, shp As Shape, sshp As Shape, eft As Effect
    Dim x!, y!, w!, h!, sw!, sh!, i&, j&, id&
    Set hshp = oSld.Shapes("Hint")
    sw = hshp.Width: sh = hshp.Height
    y = (oSld.Shapes("Scrambled").Top + oSld.Shapes("Scrambled").Height)
    y = y + (oSld.Shapes("Unscrambled").Top - y) / 2
    
    Call delShapes(oSld, "Hint_*")
    Call delShapes(oSld, "Uns_*")
    With oSld.Shapes("Unscrambled").TextFrame.TextRange
        For i = 1 To Len(.Text)
            If .Characters(i) <> " " Then '빈칸 제외
                '힌트 트리거 도형 생성
                x = .Characters(i).BoundLeft
                w = .Characters(i).BoundWidth
                h = .Characters(i).BoundHeight
                Set shp = hshp.Duplicate(1):  DoEvents
                shp.Left = x + w / 2 - sw / 2
                shp.Top = y - sh / 2
                shp.Rotation = 0
                shp.Name = "Hint_" & i
                id = oSld.TimeLine.MainSequence.FindFirstAnimationFor(oSld.Shapes("Scrambled")).Index
                Set eft = oSld.TimeLine.MainSequence.AddEffect(shp, msoAnimEffectAppear, , msoAnimTriggerAfterPrevious, id + 1)
 
                '힌트 글자 도형 생성
                With oSld.Shapes("Unscrambled")
                    Set sshp = .Duplicate(1)
                    sshp.Name = "Uns_" & i
                    sshp.ZOrder msoSendToBack
                    sshp.TextFrame2.TextRange.Font.Shadow.Visible = msoFalse
                    oSld.TimeLine.MainSequence.FindFirstAnimationFor(sshp).Delete
                End With
                With sshp.TextFrame.TextRange.Characters
                    For j = .Count To 1 Step -1
                        If j <> i Then .Characters(j).Delete
                    Next j
                End With
                sshp.Width = w  'sshp.Height = h
                sshp.Left = x
                sshp.Top = .Characters(i).BoundTop
                sshp.TextFrame.TextRange.Font.Color = rgbLightGray
                '힌트 도형 누르면 나타나기
                Set eft = oSld.TimeLine.InteractiveSequences.Add().AddTriggerEffect( _
                    sshp, msoAnimEffectFade, msoAnimTriggerOnShapeClick, shp)
                '글자 누르면 사라지기 (가려져서 미작동)
                Set eft = oSld.TimeLine.InteractiveSequences.Add().AddTriggerEffect( _
                    sshp, msoAnimEffectFade, msoAnimTriggerOnShapeClick, sshp)
                eft.Exit = msoTrue
            End If
        Next i

    End With
    
End Function

파일은 위쪽에 있습니다.

다음으로 Word Jumble 게임을 Bomb Game 형식으로 생성하는 버전도 만들어 보았습니다.

엑셀에서 취소선 대신 화살표 등 도형 표시

쵸코난 — Tue, 14 Oct 2025 08:23:02 +0900

관련: 지식인

엑셀에서 셀 내의 글자에 취소선을 적용할 수 있습니다.

그런데 단순한 직선 대신 화살표 모양 취소선을 표시하고 싶은 경우입니다.

엑셀에서 따로 취소선의 서식을 지원하지 않으므로

VBA를 이용해서 직접 그려줘야겠습니다.

아래 VBA를 이용하면 선택된 셀에 텍스트에 취소선 화살표를 그려줍니다.

화살표 모양이나 색상, 굵기 등은 코드를 수정하면 됩니다.

텍스트인경우 왼쪽 정렬해서 글자 위에 그려줍니다.

문제가 하나 있습니다.

사실, 엑셀의 텍스트로는 글자의 X/Y위치값을 알 수 없습니다.

단순하게 셀 크기 만큼의 크기로 직선을 그으면 되지만 취소선과 같은 모양으로 만들려면

텍스트의 시작이나 마지막의 X/Y좌표를 알 수 없어 직선을 그리는데 어려움이 있습니다.

파워포인트의 텍스트상자나 도형은 내부 텍스트의 Character의 X/Y좌표를 알 수 있지만

엑셀에서는 이 기능을 제공하지 않습니다.

파워포인트 개체로 만들어서 복사해올 수는 있겠으나 너무 번거롭습니다.

그래서 여기서는

엑셀 시트상에 임시로 텍스트 상자를 그려봐서 그 위치를 통해 화살표를 그리도록 했습니다.

그렇기 때문에 간단한 것 같지만 코드가 길어졌습니다.

Sub addStrikeThrough()

    Dim rng As Range, sht As Worksheet
    Dim shp As Shape, shpT As Shape
    Dim x1!, x2!, y!, m!
    
    Set sht = ActiveSheet
    If ActiveWindow.Selection Is Nothing Then Exit Sub

    For Each rng In ActiveWindow.Selection
        
        '임시 텍스트상자 그리기
        Set shp = sht.Shapes.AddTextbox(msoTextOrientationHorizontal, rng.Left, rng.Top, rng.Width, rng.Height)
        With shp.TextFrame
            .HorizontalAlignment = rng.HorizontalAlignment
            .VerticalAlignment = rng.VerticalAlignment
            .Characters.Text = rng.Text
            .Characters.Font.Size = rng.Font.Size
            .Characters.Font.Name = rng.Font.Name
            .MarginLeft = 0:    .MarginRight = 0
            .MarginTop = 0:     .MarginBottom = 0
            .AutoSize = True
        End With
        DoEvents
        m = 2   '여백
        x1 = shp.Left
        x2 = shp.Left + shp.Width + m
        If rng.HorizontalAlignment = xlGeneral Then '데이터유형에 따른 일반정렬인 경우
            If IsNumeric(rng.Text) Then
                x1 = x1 + (rng.Width - shp.Width) - m
                x2 = x1 + shp.Width + m
            End If
        End If
        y = shp.Top + shp.Height / 2
        shp.Delete
        
        '화살표 그리기
        'y = rng.Top + rng.Height / 2
        'x1 = rng.Left + m
        'x2 = rng.Left + rng.Width - m * 2
        Set shp = sht.Shapes.AddLine(x1, y, x2, y)
        With shp.Line
            .Weight = 1
            .ForeColor.RGB = rgbTeal
            .EndArrowheadStyle = msoArrowheadTriangle
            .EndArrowheadLength = msoArrowheadLong
            .EndArrowheadWidth = msoArrowheadWide
        End With
        shp.Name = "ST_" & rng.Address(False, False)
        shp.Placement = xlMove
        
    Next rng

End Sub

위 매크로를 빠른 실행에 추가하면 단축키로 실행 가능합니다.

셀을 선택하고 Alt+F8등으로 매크로 addStrikeThrough를 실행하면 화살표를 추가하고

아래의 delStrikeThrough 를 실행하면 선택된 셀 위의 화살표를 지워줍니다.

Sub delStrikeThrough()
    
    Dim sht As Worksheet
    Dim rng As Range
    Dim l As Long, shp As Shape
    
    Set sht = ActiveSheet
    For l = sht.Shapes.Count To 1 Step -1
        Set shp = sht.Shapes(l)
        If shp.Name Like "ST_*" Then
            For Each rng In ActiveWindow.Selection
                If shp.TopLeftCell.Address = rng.Address Then
                    shp.Delete
                    Exit For
                End If
            Next rng
        End If
    Next l
End Sub

실행화면:

취소선의 서식은 코드의 아래 부분을 수정하세요.

선의 두께, 색상, 시작/끝 화살표의 모양/길이/폭 등을 수정할 수 있습니다.

도형이므로 그림자, 반사, 네온, 3차원효과 등 도형효과도 적용 가능합니다.

        With shp.Line
            .Weight = 1
            .ForeColor.RGB = rgbTeal
            .EndArrowheadStyle = msoArrowheadTriangle
            .EndArrowheadLength = msoArrowheadLong
            .EndArrowheadWidth = msoArrowheadWide
        End With

테스트는 첨부파일 참고하세요.

통합 문서1.xlsm

0.02MB

konahn A PowerPoint VBA Adventurer

[Bomb Game] 상시 점수판 + Bomb 퀴즈 만들기 - PPT 스킬 퀴즈

연결로 삽입된 미디어 경로 일괄 수정

엑셀링크목록 브라우저 북마크에 일괄로 추가하기

구글 시트에서 바로 사용 가능한 AI 함수

실시간 도서 ISBN 코드로 재고 수량 조회

멜론 노래 정보 가져와서 음악파일명 일괄 변경하기

파워포인트 원하는 편집 슬라이드로 바로 이동

엑셀 데이터를 다른 창 입력란에 자동으로 일괄 붙여넣기

엑셀로 영상 편집하기?

엑셀 독립된 새로운 인스턴스로 추가 실행

슬라이드쇼에서 엔터를 치면 무조건 다음 슬라이드로 이동

[엑셀+PPT] 초성게임 자동 생성기

Word Jumble + Bomb Game 영어/한글 단어 맞추기 게임 자동 생성기 v2

활용방법

Word Jumble 영어단어 철자순서 맞추기 게임 자동 생성기 v1

Word Jumble 게임은

첫번째 버전입니다.

엑셀에서 취소선 대신 화살표 등 도형 표시

konahn　　　　　　　A PowerPoint VBA Adventurer