테이블(표) 윤곽선 따라 가이드 선 자동 추가

 

관련: 지식인

 

엑셀은 셀이 작아서 Alt키를 누른 채로 마우스로 도형을 움직이면 자석처럼 맞춰줍니다.

하지만 파워포인트는 테이블(표)의 크기가 다양해서 그런지 표의 경계에 맞게 이동시켜주지 않습니다.

단축키는 따로 없는 것으로 압니다.

​

방법은 표의 경계선에 맞게 가이드를 추가하는 것입니다.

보기 > 눈금자를 켜고 마우스로 가로와 세로로 가이드를 그려야 하는데 셀이 많으면 번거롭고 경계선에 맞게 그리는 것도 어렵습니다.

​

이 때 아래 VBA코드를 이용하면 자동으로 눈금자를 그릴 수 있습니다.

 

표(테이블)의 셀의 경계에 맞춰서 도형을 이동하고자 할 때

편하게 맞출 수 있도록 가이드(Guide)선을 자동으로 추가하는 코드입니다.

 

 

 

alt-F11 창에서 삽입 > 모듈을 추가하고 나서 코드를 붙여넣고 코드창을 닫은 다음

원하는 표를 선택한 상태에서 Alt-F8을 누르고 DrawGuides 를 실행하면 됩니다.

​

위 코드를 실행하면 현재 선택된 첫번째 표의 경계선을 따라서 가이드를 가로, 세로로 그려줍니다.

특히 첫번째 행과 첫번째 열을 기준으로 가이드 위치를 맞춰줍니다.

 

가이드가 있기 때문에 도형을 가이드/표의 경계선에 맞게 움직일 수 있습니다.

removeGuides를 실행하면 다시 모든 가이드를 삭제해줍니다.

 

 

코드:

Option Explicit

Sub DrawGuides()

    Dim pres As Presentation
    Dim i As Integer, r As Integer, c As Integer
    Dim sld As Slide, shp As Shape
    
    Set pres = ActivePresentation
    Set sld = ActiveWindow.View.Slide
    
    On Error Resume Next
    Set shp = ActiveWindow.Selection.ShapeRange(1)
    If shp.Type <> msoTable Then MsgBox "테이블(표)를 선택하세요.": Exit Sub
    On Error GoTo 0
    
    Call removeGuides
            
    'draw guides along table borders
    With shp.Table
        'Horizontal
        pres.Guides.Add ppHorizontalGuide, shp.Top
        For r = 1 To .Rows.Count
            pres.Guides.Add ppHorizontalGuide, .Cell(r, 1).Shape.Top + .Cell(r, 1).Shape.Height
        Next r
        'Vertical
        pres.Guides.Add ppVerticalGuide, shp.Left
        For c = 1 To .Columns.Count
            pres.Guides.Add ppVerticalGuide, .Cell(1, c).Shape.Left + .Cell(1, c).Shape.Width
        Next c
    End With
    
End Sub

Sub removeGuides()
    Dim pres As Presentation
    Dim i As Integer
    
    Set pres = ActivePresentation
    With pres.Guides
        'remove previous guides
        For i = .Count To 1 Step -1
            .Item(i).Delete
        Next i
    End With
End Sub

 

 

샘플 파일 참고하세요.

 

DrawGuidesAlongTableBorders1.pptm

0.05MB