[PPT 추가기능] 특정 인쇄 옵션을 항상 유지 시키기

예를 들어, 현재 슬라이드만 인쇄하고 싶은데 종종 아무 생각 없이 인쇄를 누르다 보니 모든 슬라이드가 인쇄되어 종이가 낭비될 수 있습니다.

 

인쇄 설정을 바꾸려면 사용자가 아래처럼 인쇄 옵션에서 '현재 슬라이드 인쇄'로 설정을 바꿔줘야 합니다.

하지만 특정 인쇄 옵션을 유지시키는 옵션이나 기능을 따로 제공하지는 않습니다.

​

만일 VBA를 이용하자면 아래와 같은 명령으로 현재 슬라이드만 인쇄하게 인쇄 옵션을 설정할 수 있습니다.

그밖에 칼라/흑백, 숨긴 슬라이드 인쇄 여부, 인쇄 범위, 용지에 맞게 인쇄 여부 등도 설정 가능합니다.

​

문제는 이 명령을 실행해줘야하는데 파워포인트는 그 시기를 알 수 없습니다.

​

이런 경우 파워포인트 이벤트를 감시하는 추가기능(Add-In)을 만들어서

파일이 열리는 이벤트를 감지해서 그 때마다 위 명령을 실행하도록 해줘야 합니다.

​

 

초보자인 경우 1. 맨 아래 첨부한 ppam 파일을 다운 받고 2. 마우스 우클릭, 파일 속성에서 차단해제에 체크/확인합니다. 3. 그리고 아래 4번으로 넘어가서 추가기능을 설치하고 파워포인트 재시작하세요. 다른 옵션을 원하면 pptm을 다운 받아서 차단해제, 매크로 허용해서 열고 Alt+f11 창에서 주석을 참고해서 수정하고 다른이름으로 저장에서 ppam으로 저장하세요.

  

 원리를 알고 싶거나 직접 추가기능을 만들려면 아래 1~3번을 참고하세요.

 

1. 새파일을 시작하고 Alt+F11창을 열고 먼저 Class를 추가하고 아래와 같은 코드를 입력합니다.

특정 이벤트(파일을 열거나 시작)가 발생할 때마다 이를 감지하여 반응하는 클래스를 선언하는 역할입니다.

자세한 변수나 함수의 역할은 주석을 참고하세요.

'파워포인트 이벤트를 감시할 클래스 선언
Public WithEvents App As Application

'기존 파일을 여는 이벤트가 발생할 때마다 호출
Sub App_PresentationOpen(ByVal oPres As Presentation)
    
    Module1.SetPrintOptions
    
End Sub

'새 파일을 시작할 때 호출
Sub App_AfterNewPresentation(ByVal oPres As Presentation)
    
    Module1.SetPrintOptions

End Sub

​

2. 다음으로 삽입> 모듈을 하나 추가하고 아래 코드를 입력합니다.

추가기능이 로드되면 클래스와 파워포인트를 연결하고 이벤트 발생시 프린트 옵션을 설정하는 역할입니다.

 

Dim cls As New Class1

'추가기능(Add-in)이 로드될 때 자동 실행(추가기능일 때만 호출됨, 일반 pptm의 경우 CustomUI.XML방식 이용)
Sub Auto_Open()
    
    '파워포인트 이벤트를 감시하도록 애플리케이션과 클래스를 연결
    Set cls.App = Application

End Sub

Sub SetPrintOptions()
    
    With ActivePresentation.PrintOptions
        .RangeType = ppPrintCurrent         '현재 페이지만
        '.FitToPage = msoTrue                '용지 크기에 맞춤
        '.HighQuality = msoTrue              '고품질
        '.NumberOfCopies = 1                 '인쇄 매수
        '.OutputType = ppPrintOutputSlides   '출력 타입
        '.PrintColorType = ppPrintColor      '칼라/흑백
        '.PrintHiddenSlides = msoFalse       '숨겨진 슬라이드 인쇄
    End With
    
End Sub

다른 인쇄 옵션도 원하는 대로 설정할 수 있는데 위 주석을 참고하세요.

​

3. 이제 파일 > 다른이름으로 저장에서 ppam 형식으로 기본 Addins 폴더에 저장합니다.

다른 경로에 저장해도 되지만 초보자의 경우 기본으로 열리는 사용자\AppData\Roaming\Microsoft\Addins폴더를 추천합니다.

 

 

물론 ppam 을 다른 폴더에 저장했다가 추가기능 설치창에서 불러와도 됩니다. 특정폴더에 추가기능을 모아놓으면 시스템을 초기화하는 경우 재설치하기 용이한 장점이 있습니다.

​

4. 마지막으로 추가기능을 설치합니다.

파일 > 옵션 > 추가기능 > Powerpoint추가기능 > 이동> 새로 설치 에서 KeepPrintOptions1.ppam을 찾아서 설치

나중에 기능이 필요 없어지면 다시 추가기능 목록에서 체크를 잠시 해제하거나 '제거'를 눌러주면 됩니다.

​

5. 이제 파워포인트를 재시작해서 추가기능이 로드되도록 합니다.

(참고로 시작할 때 Ctrl을 누른 채로 시작하면 추가기능 없이 안전모드로 시작합니다.)

​

파일을 새로 시작하거나 기존 파일을 열고 나서

파일 > 인쇄에서 '현재 슬라이드 인쇄'인지 확인합니다. 끝.

​

첨부파일을 다운로드해서 설치해도 됩니다.

다운로드한 경우 파일 속성에서 '차단해제'에 체크 후 확인하고 열 때 반드시 매크로를 허용해야 합니다.

KeepPrintOptions1.pptm

0.04MB

KeepPrintOptions1.ppam

0.01MB

 

 

관련: 지식인