파워포인트 슬라이드 노트를 TTS 나레이션으로 자동으로 삽입하는 매크로

파워포인트 슬라이드 노트를  TTS 나레이션으로 자동으로 삽입하는 매크로

[Note to TTS] An automation tool that converts every text note on each slide to an auto-playing sound effect. 

노트 메모를 TTS음성으로 변환하여 삽입해줍니다.

Alt-F8로 매크로를 실행하면 각 슬라이드의 노트에 적힌 내용을 

TTS사운드로 변환하여 자동으로 재생되도록  각 슬라이드에 삽입합니다.

Alt-F8 will Convert All Text Notes to 

auto-playing TTS Sound Effects for you so that they will play automatically  on entering each slide .

본 매크로는 슬라이드쇼가 자동으로 재생 혹은 시연하는 환경에 적합니다. 

모든 슬라이드를 선택하고 전환메뉴에서 충분한 시간 후에 자동으로 넘어가도록 설정하세요.

너무 짧은 전환 시간을 설정한 경우 소리가 잘릴 수 있습니다.

삽입한 음성을 삭제하려면 Alt-F8로 RemoveWav를 실행하세요.

기본으로 ppt가 있는 폴더에 note(X).wav를 생성합니다. 

자동으로 삭제하려면 소스 중에 kill 구문을 주석 해제하세요.

주의사항: 한글TTS가 작동하려면 제어판에서 한글TTS용 음성이 설치되어 작동해야 합니다.

안될 경우 제어판에서 설치된 음성엔진을 확인하세요.

TTS 음성은 시스템에 설치된 기본 TTS엔진을 이용합니다. 

TTS가 작동하지 않을 경우 TTS 엔진을 먼저 설치하셔야 합니다. 

제어판 – 접근성 – 음성인식 – 텍스트 음성변환 에서 확인할 수 있습니다.

한국어 음성 파일이 설치되지 않은 경우

한국어 음성엔진(목소리 파일)을 다운 받습니다.

'혜미'라는 여성의 한국어 음성 파일 =>  28MB짜리(클릭!)  혹은  18MB짜리(클릭!) 다운로드

TTS 엔진이 설치되어 있지 않은 경우:

=> Microsoft Speech Platform(클릭!) 다운로드

제대로 설치가 되었다면

Alt-F11 누르고 편집창에서

도구- 참조 메뉴에 들어가서 

Microsoft Speech Object Library 가 체크되어 있어야 합니다.

매크로 소스입니다:

    Sub Add_TTS_Notes()
        Dim sld As Slide
        
        'Remove previously inserted note sounds
        RemoveNoteWav
        
        For Each sld In ActivePresentation.Slides
            'save the note to an .wav file
            SaveTTSWav sld.SlideIndex
            'add the .wav file onto the slide
            AddTTSMedia sld.SlideIndex
        Next sld
        'ActivePresentation.Save
    End Sub
    
    'save the slide's note in a .wav file
    Function SaveTTSWav(idx As Long)
        Const SAFT48kHz16BitStereo = 39
        Const SSFMCreateForWrite = 3
        Dim oSpeaker As New SpeechLib.SpVoice
        Dim oStream As New SpeechLib.SpFileStream
        
        oStream.Format.Type = SAFT48kHz16BitStereo
        'filename to save: ex) note1.wav
        oStream.Open ActivePresentation.Path & "\note" & idx & ".wav", SSFMCreateForWrite, False
        oSpeaker.Volume = 100   '%
        oSpeaker.Rate = 1       '1x speed
        oSpeaker.SynchronousSpeakTimeout = 1
        oSpeaker.AlertBoundary = SVEWordBoundary
        Set oSpeaker.AudioOutputStream = oStream
        
        oSpeaker.Speak ActivePresentation.Slides(idx).NotesPage.Shapes.Placeholders(2).TextFrame.TextRange.text, SVSFNLPSpeakPunc
        oStream.Close
    End Function
    
    'insert the .wav and make it play automatically
    Function AddTTSMedia(idx As Long)
        Dim sld As Slide
        Dim shp As Shape
        Dim eft As Effect
        
        Dim wavfile As String
        
        wavfile = ActivePresentation.Path & "\note" & idx & ".wav"
        If Len(Dir(wavfile)) = 0 Then Exit Function
        Set sld = ActivePresentation.Slides(idx)
        Set shp = sld.Shapes.AddMediaObject2(wavfile, False, msoTrue, 0, 0, 20, 20)
        'shp.Name = Mid(wavfile, InStrRev(wavfile, "\") + 1) '.wav filename
        Set eft = sld.TimeLine.MainSequence.AddEffect(shp, msoAnimEffectMediaPlay, , msoAnimTriggerWithPrevious)
        eft.MoveTo 1    'make it the first effect
        With eft.EffectInformation.PlaySettings 'shp.AnimationSettings.PlaySettings
            .HideWhileNotPlaying = True
            .PauseAnimation = False
            .PlayOnEntry = True
            .StopAfterSlides = 1
        End With
        'Kill wavfile
    End Function
    
    'remove all wav media(s) in each slide
    Sub RemoveNoteWav()
        Dim sld As Slide
        Dim i As Long
        For Each sld In ActivePresentation.Slides
            For i = sld.Shapes.Count To 1 Step -1
                If sld.Shapes(i).Name Like "note*.wav" Then sld.Shapes(i).Delete
            Next i
        Next sld
    End Sub
    
    Function SpeakThis(myPhrase As String)
        Dim oSpeaker As New SpeechLib.SpVoice
        
        'Set speech properties
        oSpeaker.Volume = 100 ' percent
        oSpeaker.Rate = 0.1 ' multiplier
        oSpeaker.SynchronousSpeakTimeout = 1
        oSpeaker.AlertBoundary = SVEWordBoundary
        
        If Not myPhrase = "" Then oSpeaker.Speak myPhrase, SVSFParseSapi
    End Function
    
 

샘플 파일 첨부합니다.

Note2TTSsound1.pptm

소스는 제가 StackOverflow.com 에 먼저 답변으로 올린 내용입니다.

https://stackoverflow.com/questions/53840063/onslideshowpagechange-not-running-in-presentation/53870090?noredirect=1#comment94815911_53870090