파워포인트파일 사용자 속성 관리

pptx 파일의 고급 속성에 사용자 지정 속성에는 

특별한 자신만의 일종의 '태그'를 남길 수 있습니다.

 

직접 값을 입력하고 추가/수정/삭제가 가능합니다.

VBA로도 제어할 수 있습니다.

아래 예시는 Signature 라는 항목에 "user123" 이라는 값을 남기는 예시입니다.

 

Option Explicit

Const myName As String = "user123"      '//your name
Const mySign As String = "Signature"

Sub AddSignature()
    Dim prop As DocumentProperty
    Dim Found As Boolean
       
    With ActivePresentation
        '.BuiltInDocumentProperties("author") = "user"
        For Each prop In .CustomDocumentProperties
            If prop.Name = mySign Then prop.Value = myName: Found = True: Exit For
        Next prop
        
        If Not Found Then _
            .CustomDocumentProperties.Add mySign, False, msoPropertyTypeString, myName
            
        MsgBox "Added " & mySign & " as " & myName
    End With
      
End Sub

Sub ViewSignature()
    Dim prop As DocumentProperty
    Dim Found As Boolean
    
    With ActivePresentation
        For Each prop In .CustomDocumentProperties
            If prop.Name = mySign Then MsgBox mySign & " is " & prop.Value: Found = True: Exit For
        Next prop
        
        If Not Found Then _
            MsgBox "No " & mySign & " is found.", vbInformation
    End With
      
End Sub

Sub ViewAllProperties()
    Dim prop As DocumentProperty
    
    With ActivePresentation
        For Each prop In .CustomDocumentProperties
            Debug.Print prop.Name, prop.Value, prop.Creator, prop.Type
        Next prop
    End With
      
End Sub

 

샘플 파일:

프레젠테이션1.pptm

0.04MB